home *** CD-ROM | disk | FTP | other *** search
/ Revista do CD-ROM 101 / CD-ROM 101.iso / compl / maya5ple / Install_MayaPLE5_English.exe / Maya / Data1.cab / renderGlobalsWindow.mel < prev    next >
Encoding:
Text File  |  2003-07-17  |  134.4 KB  |  4,222 lines
  1. // Copyright (C) 1997-2002 Alias|Wavefront,
  2. // a division of Silicon Graphics Limited.
  3. //
  4. // The information in this file is provided for the exclusive use of the
  5. // licensees of Alias|Wavefront.  Such users have the right to use, modify,
  6. // and incorporate this code into other products for purposes authorized
  7. // by the Alias|Wavefront license agreement, without fee.
  8. //
  9. // ALIAS|WAVEFRONT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  10. // INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  11. // EVENT SHALL ALIAS|WAVEFRONT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  12. // CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  13. // DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  14. // TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  15. // PERFORMANCE OF THIS SOFTWARE.
  16. //
  17. //
  18. //  Alias|Wavefront Script File
  19. //  MODIFY THIS AT YOUR OWN RISK
  20. //
  21. //  Creation Date:  6 November 1998
  22. //
  23. //  Description:
  24. //      This file contains all of the methods needed to run
  25. //        the Render Globals window.  Render Globals change 
  26. //        the information that is system-wide (as opposed to
  27. //        object-specific) and affects the renderer.
  28. //
  29.  
  30. //   We ignore 
  31. //            defaultRenderGlobals.useMayaFileName
  32. //            defaultRenderGlobals.animationRange
  33.  
  34.  
  35. global proc updateFileOutputFeedback ()
  36. //
  37. //  Procedure Name:
  38. //      updateFileOutputFeedback
  39. //
  40. //  Description:
  41. //      Updates lines of text that allow the user to see
  42. //        what files are going to be created when they render.
  43. //
  44. {
  45.     string $title1 = "  File Name:  ";
  46.     string $title2 = "  To:             ";
  47.  
  48.     string $prefix = `textFieldGrp -query -text fileName`;
  49.     if ($prefix == "(not set; using filename)") {
  50.         string $sceneName = `file -q -sn`;
  51.         if (size($sceneName) == 0) {
  52.             $prefix = "untitled";
  53.         } else {
  54.             string $buffer[];
  55.             tokenize $sceneName "/\\:" $buffer;
  56.             string $tail = $buffer[size($buffer) - 1];
  57.             tokenize $tail "." $buffer;
  58.             $tail = $buffer[0];
  59.             $prefix = $tail;
  60.         }
  61.     }
  62.  
  63.     // Image extension
  64.     string $imageType;
  65.     int $imageUse = `getAttr "defaultRenderGlobals.outFormatControl"`;
  66.     if ($imageUse == 1) {
  67.         // Don't use extension
  68.         $imageType = "";
  69.     } else if ($imageUse == 0) {
  70.         // Show the extension
  71.         global string $imgExt[];  // This is the actual file extension
  72.         global int $imgExtNum[];  // This is the corresponding internal value
  73.  
  74.         int $imageNum = `getAttr "defaultRenderGlobals.imageFormat"`;
  75.         for ($i=0; $i < size($imgExtNum); ++$i) {
  76.             if ($imageNum == $imgExtNum[$i]) {
  77.                 $imageType = "."+$imgExt[$i];
  78.                 break;
  79.             }
  80.         }
  81.     } else if ($imageUse == 2) {
  82.         // User specified
  83.         $imageType = "."+`getAttr "defaultRenderGlobals.outFormatExt"` ;
  84.     }
  85.     
  86.     // Frames number extension
  87.     string $frame1 = "";
  88.     string $frame2 = "";
  89.     int $useAnim = `getAttr "defaultRenderGlobals.animation"`;
  90.     if ($useAnim) {
  91.         // if useAnim, make sure it's not a movie format, or else
  92.         // bad extension names will be printed out to the window.
  93.         int $imgFormat = `getAttr "defaultRenderGlobals.imageFormat"`;
  94.         if ($imgFormat == 21 || $imgFormat == 22 || $imgFormat == 23)
  95.             $useAnim = 0;
  96.     }
  97.     if ($useAnim) {
  98.         float $byf = `getAttr defaultRenderGlobals.byFrameStep`;
  99.         if ($byf == 0.0) $byf = 0.00001;
  100.  
  101.         int $pad = `getAttr "defaultRenderGlobals.extensionPadding"`;
  102.         int $f1 = `getAttr "defaultRenderGlobals.startFrame"`;
  103.         int $f2 = `getAttr "defaultRenderGlobals.endFrame"`;
  104.         int $numFrames = ($f2 - $f1) / $byf;
  105.  
  106.         // Check to see if the numbers are being modified
  107.         if (`getAttr "defaultRenderGlobals.modifyExtension"`) {
  108.             $f1 = `getAttr defaultRenderGlobals.startExtension`;
  109.             $f2 = $f1 + ($numFrames * `getAttr defaultRenderGlobals.byExtension`);
  110.         }
  111.             
  112.         // Convert to strings
  113.         $frame1 = $f1;
  114.         $frame2 = $f2;
  115.  
  116.         // Pad the numbers
  117.         for ($i=size($frame1); $i<$pad; $i++) {
  118.             $frame1 = "0"+$frame1;
  119.         }
  120.         if (`getAttr "defaultRenderGlobals.periodInExt"`)
  121.             $frame1 = "."+$frame1;
  122.  
  123.         for ($i=size($frame2); $i<$pad; $i++) {
  124.             $frame2 = "0"+$frame2;
  125.         }
  126.         if (`getAttr "defaultRenderGlobals.periodInExt"`)
  127.             $frame2 = "."+$frame2;
  128.     }
  129.     
  130.     // Check for fields
  131.  
  132.     string $fieldExt = "";
  133.     int $whichFields = `getAttr defaultResolution.fields`;
  134.     int $useFields = ($whichFields != 0);
  135.     int $useFieldExt = (`getAttr "defaultRenderGlobals.fieldExtControl"` != 1);
  136.     int $defFieldExt = (`getAttr "defaultRenderGlobals.fieldExtControl"` == 0);
  137.     int $useCustom = (`getAttr "defaultRenderGlobals.fieldExtControl"` == 2);
  138.     
  139.     // Note that I am not using a "." in front of these.
  140.     // That's the way the code works now.  
  141.     // I think that there should be a "."
  142.     //
  143.     if ($useFields && $useFieldExt) {
  144.         // Add fields to the file name
  145.         if ($defFieldExt) {
  146.             if ($whichFields == 1) $fieldExt = "o";
  147.             if ($whichFields == 2) $fieldExt = "e";
  148.             if ($whichFields == 3 || $whichFields == 4) $fieldExt = "e (o)";
  149.         } else if ($useCustom) {
  150.             if ($whichFields == 1) $fieldExt = `getAttr "defaultRenderGlobals.oddFieldExt"`;
  151.             if ($whichFields == 2) $fieldExt = `getAttr "defaultRenderGlobals.evenFieldExt"`;
  152.             if ($whichFields == 3 || $whichFields == 4) $fieldExt = `getAttr "defaultRenderGlobals.oddFieldExt"`
  153.                 + " (" + `getAttr "defaultRenderGlobals.evenFieldExt"` + ")";
  154.         }
  155.     }
  156.  
  157.     // Now put them all together to show what is going to happen
  158.     int $frameBeforeExt = `getAttr "defaultRenderGlobals.putFrameBeforeExt"`;  // 0=ext.frame, 1=frame.ext
  159.     if ($frameBeforeExt == 0) {
  160.         text -edit -label ($title1+$prefix+$imageType+$frame1+$fieldExt) exampleText1;
  161.         if ($useAnim) {
  162.             text -edit -label ($title2+$prefix+$imageType+$frame2+$fieldExt) exampleText2;
  163.         } else {
  164.             text -edit -label "" exampleText2;
  165.         }
  166.     } else {
  167.         text -edit -label ($title1+$prefix+$frame1+$fieldExt+$imageType) exampleText1;
  168.         if ($useAnim) {
  169.             text -edit -label ($title2+$prefix+$frame2+$fieldExt+$imageType) exampleText2;
  170.         } else {
  171.             text -edit -label "" exampleText2;
  172.         }
  173.     }
  174. }
  175.  
  176. global proc int validFileNamePrefix(string $prefix)
  177. {
  178.     int $isValid = 1;
  179.  
  180.     if (match("[\\/:*?\"<>| !$]", $prefix) != "") {
  181.         // Most of these characters may not occur in NT filenames
  182.         // The ' ', '!' and '$' are troublesome on Unix.
  183.         catch (error ("File name prefix contains invalid character(s)."));
  184.         $isValid = 0;
  185.     }
  186.     return $isValid;
  187. }
  188.  
  189. global proc int multiframeFormat(string $format)
  190. {
  191.     int $isMultiframe = 0;
  192.  
  193.     $isMultiframe = $format == "qt" || $format == "avi" || $format == "mv";
  194.  
  195.     return $isMultiframe;
  196. }
  197.  
  198. //==================================================================
  199. //
  200. // Starting the UI updating section
  201. //
  202. //==================================================================
  203.  
  204. global proc updateImageDirectory ()
  205. //
  206. //  Procedure Name:
  207. //      updateImageDirectory
  208. //
  209. //  Description:
  210. //      Shows the Project image directory that the rendered
  211. //        images will be written to.
  212. //
  213. {
  214.     setParent renderGlobalsWindow;
  215.  
  216.     // relative path, get the project's image directory
  217.     //
  218.     string $fileRules[] = `workspace -q -rt`;
  219.     int $i;
  220.     string $imageDir = ""; // default
  221.     for ( $i = 0; $i < size($fileRules); $i += 2 ) {
  222.         if ( $fileRules[$i] == "images" ) {
  223.             $imageDir = "/" + $fileRules[$i+1];
  224.             break;
  225.         }
  226.     }
  227.  
  228.     $path = "  Path: "+(`workspace -q -fn` + $imageDir + "/");
  229.  
  230.     text -edit -label $path exampleText0;
  231. }
  232.  
  233. global proc updateImageFile ()
  234. //
  235. //  Procedure Name:
  236. //      updateImageFile
  237. //
  238. //  Description:
  239. //      Gets the real values from the nodes and sets the UI based
  240. //        on these values.  This procedure updates all of the values 
  241. //        that make up the image file name.
  242. //
  243. {
  244.     setParent renderGlobalsWindow;
  245.     string $globalsAttr = "defaultRenderGlobals.imageFilePrefix";
  246.     string $prefix = `getAttr $globalsAttr`;
  247.  
  248.     if (size($prefix) > 0) {
  249.         textFieldGrp -edit -text $prefix fileName;
  250.     } else {
  251.         textFieldGrp -edit -text "(not set; using filename)" fileName;
  252.     }
  253.  
  254.     // Extension ------------------------------------------------
  255.  
  256.     global string $imgExt[];  // This is the actual file extension
  257.     int $frameBeforeExt = `getAttr "defaultRenderGlobals.putFrameBeforeExt"`;  // 0=ext.frame, 1=frame.ext
  258.     int $activeMenuItem = 0;
  259.     int $useAnim = `getAttr "defaultRenderGlobals.animation"`;
  260.     int $imageUse = `getAttr "defaultRenderGlobals.outFormatControl"`;
  261.     int $period = `getAttr "defaultRenderGlobals.periodInExt"`;
  262.     int $ext = `optionMenuGrp -q -sl imageMenu` - 1; 
  263.     int $multiframe = multiframeFormat($imgExt[$ext]);
  264.     if ($useAnim) {
  265.         if ( $multiframe != 0 )
  266.         {
  267.             $activeMenuItem = 2;
  268.         }
  269.         else if ($imageUse == 1)
  270.         {
  271.             $activeMenuItem = 5;
  272.         }
  273.         else
  274.         {
  275.             if ($frameBeforeExt == 0) {
  276.                 $activeMenuItem = 4;
  277.             } else {
  278.                 if ($period == 0)
  279.                     $activeMenuItem = 6;
  280.                 else
  281.                     $activeMenuItem = 3;
  282.             }
  283.         }
  284.     } else {
  285.         if ($imageUse == 1) {
  286.             $activeMenuItem = 1;
  287.         } else {
  288.             $activeMenuItem = 2;
  289.         }
  290.     }
  291.     
  292.     optionMenuGrp -edit -sl $activeMenuItem extMenu;
  293.  
  294.     // Image Format ------------------------------------------------
  295.  
  296.     global string $imgExt[];  // This is the actual file extension
  297.     global int $imgExtNum[];  // This is the corresponding internal value
  298.  
  299.     int $imageNum = `getAttr "defaultRenderGlobals.imageFormat"`;
  300.     for ($i=0; $i < size($imgExtNum); ++$i) {
  301.         if ($imageNum == $imgExtNum[$i]) {
  302.             optionMenuGrp -edit -sl ($i+1) imageMenu;
  303.             break;
  304.         }
  305.     }
  306.  
  307.     // Renderable Objects ------------------------------------------------
  308.  
  309.     if (`getAttr "defaultRenderGlobals.renderAll"` == 1) {
  310.         optionMenuGrp -edit -select 1 renderObjMenu;
  311.     } else {
  312.         optionMenuGrp -edit -select 2 renderObjMenu;
  313.     }
  314. }
  315.  
  316.  
  317. global proc updateRenderableCamera ()
  318. //
  319. //  Procedure Name:
  320. //      updateRenderableCamera
  321. //
  322. //  Description:
  323. //      Gets the real values from the nodes and sets the UI based
  324. //      on these values.  This procedure updates all of the values
  325. //      that make up the renderable camera.
  326. //
  327. {
  328.     // This is a fix to get around the optionMenuGrp bug (#81337)
  329.     string $fullName = `setParent "cameraMenu"`;
  330.     string $menuName = ($fullName+"|OptionMenu");
  331.     setParent -m $menuName;
  332.  
  333.     string $allCameras[] = `ls -ca`;
  334.     string $parents[];
  335.     int    $i;
  336.     int       $numRenderable = 0;
  337.     string $cmd;
  338.  
  339.     //
  340.     // First remove any existing menuItems; we're gonna rebuild the menu
  341.     // from scratch each time.
  342.  
  343.     int $numOldMenuItems = `optionMenuGrp -q -ni cameraMenu`;
  344.     string    $oldMenuItems[] = `optionMenuGrp -q -ill cameraMenu`;
  345.  
  346.     for ($i = 0; $i < $numOldMenuItems; $i++) {
  347.         deleteUI $oldMenuItems[$i];
  348.     }
  349.  
  350.     // Run through the list of all of the cameras and build a
  351.     // optionMenu of them that the user uses to select the
  352.     // renderable camera.
  353.     //
  354.     // First count how many renderable cameras exist
  355.     //
  356.     for ($i = 0; $i < size($allCameras); $i++) {
  357.         if (`getAttr ($allCameras[$i] + ".renderable")`) {
  358.             $numRenderable++;
  359.         }
  360.     }
  361.  
  362.     int $firstRenderable = 0;
  363.     for ($i = 0; $i < size($allCameras); $i++) {
  364.         $parents = `listRelatives -p $allCameras[$i]`;
  365.         string $thisLabel = `menuItem -label $parents[0]`;
  366.         // Use the first renderable camera
  367.         if (`getAttr ($allCameras[$i] + ".renderable")`) {
  368.             $firstRenderable++;
  369.             if ($firstRenderable == 1) {
  370.  
  371.                 // Selected Camera -----------------------------------------
  372.                 optionMenuGrp -edit -sl ($i+1) cameraMenu;
  373.  
  374.                 // Channels ------------------------------------------------
  375.                 checkBoxGrp -edit -v1
  376.                     `getAttr ($allCameras[$i] + ".image")` rgbChannel;
  377.                 checkBoxGrp -edit -v1
  378.                     `getAttr ($allCameras[$i] + ".mask")` alphaChannel;
  379.                 checkBoxGrp -edit -v1
  380.                     `getAttr ($allCameras[$i] + ".depth")` depthChannel;
  381.             }
  382.             if ($numRenderable > 1) {
  383.                 string $camLabel = $parents[0] + " (Renderable)";
  384.                 menuItem -edit -label $camLabel $thisLabel;
  385.             }
  386.         }
  387.     }
  388. }
  389.  
  390. global proc updateFrames ()
  391. //
  392. //  Procedure Name:
  393. //      updateFrames
  394. //
  395. //  Description:
  396. //      Gets the real values from the nodes and sets the UI based
  397. //        on these values.  This procedure updates all of the values 
  398. //        that make up the animation frame numbers.
  399. //
  400. {
  401.     int $useAnim = `getAttr "defaultRenderGlobals.animation"`;
  402.  
  403.     // print( "updateFrames: animation " + $useAnim + "\n" );
  404.  
  405.     // Frames numbers ------------------------------------------------
  406.  
  407.     floatFieldGrp -edit
  408.         -v1 `getAttr "defaultRenderGlobals.startFrame"`
  409.         -enable $useAnim
  410.         startFrame;
  411.  
  412.     floatFieldGrp -edit
  413.         -v1 `getAttr "defaultRenderGlobals.endFrame"`
  414.         -enable $useAnim
  415.         endFrame;
  416.  
  417.     floatFieldGrp -edit
  418.         -v1 `getAttr "defaultRenderGlobals.byFrameStep"`
  419.         -enable $useAnim
  420.         frameStep;
  421.  
  422.     intFieldGrp -edit
  423.         -v1 `getAttr "defaultRenderGlobals.extensionPadding"`
  424.         -enable $useAnim
  425.         extPad;
  426.         
  427.     // Frames Options ------------------------------------------------
  428.  
  429.     // Only Update these if they exist.
  430.     // The frame may not have been created yet.
  431.     //
  432.     if (`checkBoxGrp -exists frameCheckBox`) {
  433.     
  434.         int $modExt = `getAttr "defaultRenderGlobals.modifyExtension"`;
  435.         checkBoxGrp -edit
  436.             -v1 $modExt
  437.             -enable $useAnim
  438.             frameCheckBox;
  439.         
  440.         intFieldGrp -edit 
  441.             -v1 `getAttr "defaultRenderGlobals.startExtension"`
  442.             -enable ($useAnim && $modExt)
  443.             frameStartOverride;
  444.         
  445.         intFieldGrp -edit
  446.             -v1 `getAttr "defaultRenderGlobals.byExtension"`
  447.             -enable ($useAnim && $modExt)
  448.             frameByOverride;
  449.     }
  450. }
  451.  
  452. global proc updateExtOptions ()
  453. //
  454. //  Procedure Name:
  455. //      updateExtOptions
  456. //
  457. //  Description:
  458. //      Gets the real values from the nodes and sets the UI based
  459. //        on these values.  This procedure updates the custom extension.
  460. //
  461. {
  462.     int $useImage = (`getAttr "defaultRenderGlobals.outFormatControl"` != 1);
  463.     checkBoxGrp -edit 
  464.         -v1 (`getAttr "defaultRenderGlobals.outFormatControl"` == 2)
  465.         -enable $useImage
  466.         imageCheckBox;
  467.         
  468.     int $useExt = $useImage && `checkBoxGrp -q -v1 imageCheckBox`;
  469.     textFieldGrp -edit
  470.         -enable $useExt
  471.         -text `getAttr "defaultRenderGlobals.outFormatExt"` 
  472.         userExt;
  473. }
  474.  
  475. global proc updateFieldOptions ()
  476. //
  477. //  Procedure Name:
  478. //      updateFieldOptions
  479. //
  480. //  Description:
  481. //      Gets the real values from the nodes and sets the UI based
  482. //        on these values.  This procedure updates all of the field
  483. //        values.
  484. //
  485. {
  486.     int $fieldType = `getAttr defaultResolution.fields` + 1;
  487.     int $useFields = ($fieldType != 1);
  488.     int $autoInterlace = ($fieldType == 4);
  489.  
  490.     // Because of 123444, the ordering of the menu and the actual
  491.     // saved fields values are not the same, which is why the
  492.     // below convoluted code.
  493.     switch ($fieldType) {
  494.         case 1:
  495.             optionMenuGrp -edit -select 1 fieldMenu;
  496.             break;
  497.         case 2:
  498.         case 3:
  499.             optionMenuGrp -edit -select ($fieldType + 2) fieldMenu;
  500.             break;
  501.         case 4:
  502.         case 5:
  503.             optionMenuGrp -edit -select ($fieldType - 2) fieldMenu;
  504.             break;
  505.     }
  506.         
  507.  
  508.     optionMenuGrp -edit -enable $useFields fieldDominanceMenu;
  509.     int $oddFieldFirst = `getAttr defaultResolution.oddFieldFirst`;
  510.     int $whichDominance = $oddFieldFirst ? 1 : 2;
  511.     optionMenuGrp -edit -sl $whichDominance fieldDominanceMenu;
  512.  
  513.     if ($fieldType == 1 || $fieldType == 4)
  514.         radioButtonGrp -edit
  515.             -select (`getAttr defaultResolution.zerothScanline` + 1)
  516.             -enable 0
  517.             scanlineButtons;
  518.     else
  519.         radioButtonGrp -edit
  520.             -select (`getAttr defaultResolution.zerothScanline` + 1)
  521.             -enable 1
  522.             scanlineButtons;
  523.     
  524.     int $useCustom = 0;    
  525.     if (`getAttr "defaultRenderGlobals.fieldExtControl"` == 1)
  526.         radioButtonGrp -edit -select 1 fieldButton1;
  527.     else if (`getAttr "defaultRenderGlobals.fieldExtControl"` == 0) 
  528.         radioButtonGrp -edit -select 1 fieldButton2;
  529.     else {
  530.         radioButtonGrp -edit -select 1 fieldButton3;
  531.         $useCustom = 1;
  532.     }
  533.     
  534.     radioButtonGrp -edit -enable ($useFields && !$autoInterlace) fieldButton1;
  535.     radioButtonGrp -edit -enable ($useFields && !$autoInterlace) fieldButton2;
  536.     radioButtonGrp -edit -enable ($useFields && !$autoInterlace) fieldButton3;
  537.  
  538.     textFieldGrp -edit
  539.         -text `getAttr "defaultRenderGlobals.oddFieldExt"`
  540.         -enable ($useFields && $useCustom)
  541.         oddFieldExt;
  542.         
  543.     textFieldGrp -edit
  544.         -text `getAttr "defaultRenderGlobals.evenFieldExt"`
  545.         -enable ($useFields && $useCustom)
  546.         evenFieldExt;
  547. }
  548.  
  549. global proc updateResolution ()
  550. //
  551. //  Procedure Name:
  552. //      updateResolution
  553. //
  554. //  Description:
  555. //      Gets the real values from the nodes and sets the UI based
  556. //        on these values.  This procedure updates all of the resolution
  557. //        values.
  558. //
  559. {
  560.     int $width = `getAttr defaultResolution.width`;
  561.     int $height = `getAttr defaultResolution.height`;
  562.     float $aspect = `getAttr defaultResolution.deviceAspectRatio`;
  563.     int $resItem;
  564.     int $whichRes = 1; // use "Custom" if no match is found
  565.     string $allResNodes[] = `ls -type resolution`;
  566.  
  567.     global string   $gImageFormatData[];
  568.     global string   $gUserImageFormatData[];
  569.     int        $numResolutionPresets = size($gImageFormatData);
  570.     int        $numUserResolutionPresets = size($gUserImageFormatData);
  571.     int        $numResolutionNodePresets = size($allResNodes) - 1;
  572.     int        $resWidth;
  573.     int        $resHeight;
  574.     float    $resAspect;
  575.     int        $numTokens;
  576.     string    $tokens[];
  577.  
  578.     for ($resItem = 0; $resItem < $numResolutionPresets; $resItem++) {
  579.         string $item = $gImageFormatData[$resItem];
  580.         $numTokens = tokenize($item, $tokens);
  581.         if ($numTokens == 4) {
  582.             $resWidth = $tokens[1];
  583.             $resHeight = $tokens[2];
  584.             $resAspect = $tokens[3];
  585.             if ($width == $resWidth && $height == $resHeight
  586.                     && abs($aspect - $resAspect) < 0.001) {
  587.                 // We add _2_ to $resItem below: 1 because we're
  588.                 // skipping the first item (Custom) in the list, and 1
  589.                 // because the optionMenu items are numbered starting at 1,
  590.                 // but our list in $gImageFormatData is indexed starting at 0.
  591.                 $whichRes = $resItem + 2;
  592.                 break;
  593.             }
  594.         } else {
  595.             string $badFormatMsg
  596.                 = ("Found invalid image format description: \""
  597.                 + $item + "\" in imageFormats.mel");
  598.             warning $badFormatMsg;
  599.         }
  600.     }
  601.  
  602.     // If no match was found in the built-in resolutions,
  603.     // check out the user-defined ones
  604.     //
  605.     if ($whichRes == 1) {
  606.         for ($resItem = 0; $resItem < $numUserResolutionPresets; $resItem++) {
  607.             string $item = $gUserImageFormatData[$resItem];
  608.             $numTokens = tokenize($item, $tokens);
  609.             if ($numTokens == 4) {
  610.                 $resWidth = $tokens[1];
  611.                 $resHeight = $tokens[2];
  612.                 $resAspect = $tokens[3];
  613.                 if ($width == $resWidth && $height == $resHeight
  614.                         && abs($aspect - $resAspect) < 0.001) {
  615.                     $whichRes = $numResolutionPresets + $resItem + 2;
  616.                     break;
  617.                 }
  618.             } else {
  619.                 string $badFormatMsg
  620.                     = ("Found invalid image format description: \""
  621.                     + $item + "\" in userImageFormats.mel");
  622.                 warning $badFormatMsg;
  623.             }
  624.         }
  625.     }
  626.  
  627.     // If no match was found in the user-defined resolutions,
  628.     // see if there are any 'extra' resolution nodes in the scene.
  629.     //
  630.     if ($whichRes == 1) {
  631.         for ($resItem = 0; $resItem < $numResolutionNodePresets; $resItem++) {
  632.             //
  633.             // We assume the 0th item in the list of resolution nodes is
  634.             // the default one, which is created implicitly...
  635.             string $resNodeName = $allResNodes[$resItem + 1];
  636.  
  637.             $resWidth = `getAttr ($resNodeName + ".width")`;
  638.             $resHeight = `getAttr ($resNodeName + ".height")`;
  639.             $resAspect = `getAttr ($resNodeName + ".deviceAspectRatio")`;
  640.             if ($width == $resWidth && $height == $resHeight
  641.                     && abs($aspect - $resAspect) < 0.001) {
  642.                 // We add _2_ to $resItem below: 1 because we're
  643.                 // skipping the first item (Custom) in the list, and 1
  644.                 // because the optionMenu items are numbered starting at 1,
  645.                 // but our list in $gImageFormatData is indexed starting at 0.
  646.                 $whichRes = $numResolutionPresets
  647.                             + $numUserResolutionPresets + $resItem + 2;
  648.                 break;
  649.             }
  650.         }
  651.     }
  652.     optionMenuGrp -edit -sl $whichRes resolutionMenu;
  653.  
  654.     checkBoxGrp -edit -v1 `getAttr defaultResolution.aspectLock` aspectLockCheck;
  655.     intFieldGrp -edit -v1 $width resWidth;
  656.     intFieldGrp -edit -v1 $height resHeight;
  657.     floatFieldGrp -edit -v1 $aspect resRatio;
  658.     rgAdjustPixelAspect "defaultResolution";
  659.     checkBoxGrp -edit -v1 `getAttr defaultResolution.lockDeviceAspectRatio` ratioLockCheck;
  660. }
  661.  
  662. global proc updateRaytraceQuality ()
  663. //
  664. //  Procedure Name:
  665. //      updateRaytraceQuality
  666. //
  667. //  Description:
  668. //      Gets the real values from the nodes and sets the UI based
  669. //        on these values.  This procedure updates all of the quality
  670. //        values.
  671. //
  672. {
  673.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  674.     int $useRT = `getAttr ($rendQual[0] + ".enableRaytracing")`;
  675.     checkBoxGrp -edit -v1 $useRT raytraceCheck;
  676.  
  677.     intSliderGrp -edit -v `getAttr ($rendQual[0] + ".reflections")`
  678.         reflectionsField;
  679.  
  680.     intSliderGrp -edit -v `getAttr ($rendQual[0] + ".refractions")`
  681.         refractionsField;
  682.  
  683.     intSliderGrp -edit -v `getAttr ($rendQual[0] + ".shadows")`
  684.         shadowsField;
  685.  
  686.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".rayTraceBias")`
  687.         rayTraceBiasField;
  688.  
  689.     intSliderGrp -edit -enable $useRT reflectionsField;
  690.     intSliderGrp -edit -enable $useRT refractionsField;
  691.     intSliderGrp -edit -enable $useRT shadowsField;
  692.     floatSliderGrp -edit -enable $useRT rayTraceBiasField;
  693. }
  694.  
  695. global proc updateRenderQuality ()
  696. //
  697. //  Procedure Name:
  698. //      updateRenderQuality
  699. //
  700. //  Description:
  701. //      Gets the real values from the nodes and sets the UI based
  702. //        on these values.  This procedure updates all of the quality
  703. //        values.
  704. //
  705. {
  706.     if (!`columnLayout -exists rgQualityLayout`) {
  707.         return;
  708.     }
  709.  
  710.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  711.  
  712.     int $useBlur = `getAttr defaultRenderGlobals.motionBlur`;
  713.     int $blur2d = (`getAttr defaultRenderGlobals.motionBlurType` == 0);
  714.     int $enableMultiPixelFilter = false;
  715.     int $enableFilterAttrs = false;
  716.  
  717.     int $shadingSamples = `getAttr ($rendQual[0] + ".shadingSamples")`;
  718.     intSliderGrp -edit -v $shadingSamples shadingSamplesField;
  719.  
  720.     int $maxShadingSamples = `getAttr ($rendQual[0] + ".maxShadingSamples")`;
  721.     intSliderGrp -edit -v $maxShadingSamples maxShadingSamplesField;
  722.  
  723.     int $visibilitySamples = `getAttr ($rendQual[0] + ".visibilitySamples")`;
  724.     intSliderGrp -edit -v $visibilitySamples visSamplesField;
  725.  
  726.     int $maxVisibilitySamples
  727.         = `getAttr ($rendQual[0] + ".maxVisibilitySamples")`;
  728.     intSliderGrp -edit -v $maxVisibilitySamples maxVisSamplesField;
  729.  
  730.     int $particleSamples = `getAttr ($rendQual[0] + ".particleSamples")`;
  731.     intSliderGrp -edit -v $particleSamples particlesSamplesField;
  732.                 
  733.     //
  734.     // The edge AA settings go from 0-3 for Highest down to Low
  735.     // But we choose to display the menu items in _ascending_ order,
  736.     // for consistency with the order of presets.
  737.     // Thus we must remap the values here
  738.     //
  739.     int $edgeAA = `getAttr ($rendQual[0] + ".edgeAntiAliasing")`;
  740.     int $edgeMenuItem;
  741.     if ($edgeAA == 0) { // Highest
  742.         $edgeMenuItem = 4;
  743.     } else if ($edgeAA == 1) { // High
  744.         $edgeMenuItem = 3;
  745.     } else if ($edgeAA == 2) { // Medium
  746.         $edgeMenuItem = 2;
  747.     } else if ($edgeAA == 3) { // Low
  748.         $edgeMenuItem = 1;
  749.     }
  750.     optionMenuGrp -edit -sl $edgeMenuItem edgeMenu;
  751.  
  752.     int $useMultiPixelFilter
  753.         = `getAttr ($rendQual[0] + ".useMultiPixelFilter")`;
  754.     checkBoxGrp -edit -v1 $useMultiPixelFilter pixelCheck;
  755.  
  756.  
  757.     //
  758.     // Check against the contrast threshold values.  The below
  759.     // tolerance check is due to MEL's poor numerical accuracy.
  760.     // E.g., setting a 0.4 value will not result in a 0.4 setting.
  761.     //
  762.     float $numerialTol = 0.001;
  763.     float $highContrastRed = 0.4;
  764.     float $highContrastGreen = 0.3;
  765.     float $highContrastBlue = 0.6;
  766.     float $lowContrastRed = 0.2;
  767.     float $lowContrastGreen = 0.15;
  768.     float $lowContrastBlue = 0.3;
  769.  
  770.     float $redTol = `getAttr ($rendQual[0] + ".redThreshold")`;
  771.     float $greenTol = `getAttr ($rendQual[0] + ".greenThreshold")`;
  772.     float $blueTol = `getAttr ($rendQual[0] + ".blueThreshold")`;
  773.  
  774.     float $redDiff = $redTol - $highContrastRed;
  775.     float $greenDiff = $greenTol - $highContrastGreen;
  776.     float $blueDiff = $blueTol - $highContrastBlue;
  777.     int $highContrast = $redDiff < $numerialTol && $redDiff > -$numerialTol &&
  778.                         $greenDiff < $numerialTol && $greenDiff > -$numerialTol &&
  779.                         $blueDiff < $numerialTol && $blueDiff > -$numerialTol;
  780.     
  781.     $redDiff = $redTol - $lowContrastRed;
  782.     $greenDiff = $greenTol - $lowContrastGreen;
  783.     $blueDiff = $blueTol - $lowContrastBlue;
  784.     int $lowContrast = $redDiff < $numerialTol && $redDiff > -$numerialTol &&
  785.                        $greenDiff < $numerialTol && $greenDiff > -$numerialTol &&
  786.                        $blueDiff < $numerialTol && $blueDiff > -$numerialTol;
  787.  
  788.  
  789.     //
  790.     // See if the current settings of the 6 attributes we just queried
  791.     // match any preset settings, and set the Presets menu state
  792.     // accordingly
  793.     //
  794.     if ($shadingSamples == 1 && $maxShadingSamples == 1
  795.             && $visibilitySamples == 1 && $maxVisibilitySamples == 4
  796.             && $edgeAA == 3  && $useMultiPixelFilter == 0 && $highContrast) {
  797.         optionMenuGrp -edit -sl 2 qualityPresetMenu; // Preview Quality
  798.     } else if ($shadingSamples == 1 && $maxShadingSamples == 8
  799.             && $visibilitySamples == 1 && $maxVisibilitySamples == 4
  800.             && $edgeAA == 0  && $useMultiPixelFilter == 0 && $highContrast) {
  801.         optionMenuGrp -edit -sl 3 qualityPresetMenu; // Intermediate Quality
  802.     } else if ($shadingSamples == 2 && $maxShadingSamples == 8
  803.             && $visibilitySamples == 1 && $maxVisibilitySamples == 4
  804.             && $edgeAA == 0  && $useMultiPixelFilter == 1 && $highContrast) {
  805.         optionMenuGrp -edit -sl 4 qualityPresetMenu; // Production Quality
  806.     } else if ($shadingSamples == 2 && $maxShadingSamples == 8
  807.             && $visibilitySamples == 1 && $maxVisibilitySamples == 4
  808.             && $edgeAA == 0  && $useMultiPixelFilter == 1 && $lowContrast) {
  809.         optionMenuGrp -edit -sl 5 qualityPresetMenu; // Contrast Sensitive Production Quality
  810.     } else if ($shadingSamples == 3 && $maxShadingSamples == 8
  811.             && $visibilitySamples == 1 && $maxVisibilitySamples == 4
  812.             && $edgeAA == 0  && $useMultiPixelFilter == 1 && $highContrast) {
  813.         optionMenuGrp -edit -sl 6 qualityPresetMenu; // Motion Blur Production
  814.     } else {
  815.         optionMenuGrp -edit -sl 1 qualityPresetMenu; // custom
  816.     }
  817.  
  818.     int $filterType = `getAttr ($rendQual[0] + ".pixelFilterType")`;
  819.     if ($filterType == 0) { // Box Filter
  820.         optionMenuGrp -edit -sl 1 pixelFilterMenu;
  821.     } else if ($filterType == 2) { // Triangle Filter
  822.         optionMenuGrp -edit -sl 2 pixelFilterMenu;
  823.     } else if ($filterType == 4) { // Gaussian Filter
  824.         optionMenuGrp -edit -sl 3 pixelFilterMenu;
  825.     } else if ($filterType == 5) { // Quadratic B-Spline Filter
  826.         optionMenuGrp -edit -sl 4 pixelFilterMenu;
  827.     } else if ($filterType == 1000) { // Plug-in Filter
  828.         optionMenuGrp -edit -sl 5 pixelFilterMenu;
  829.     }
  830.  
  831.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".pixelFilterWidthX")`
  832.         filterXField;
  833.  
  834.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".pixelFilterWidthY")`
  835.         filterYField;
  836.  
  837.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".redThreshold")`
  838.         contrastRedField;
  839.  
  840.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".greenThreshold")`
  841.         contrastGreenField;
  842.  
  843.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".blueThreshold")`
  844.         contrastBlueField;
  845.  
  846.     floatSliderGrp -edit -v `getAttr ($rendQual[0] + ".coverageThreshold")`
  847.         -enable ($useBlur && !$blur2d) contrastCoverField;
  848.  
  849.     optionMenuGrp -edit -enable $useMultiPixelFilter pixelFilterMenu;
  850.     floatSliderGrp -edit -enable $useMultiPixelFilter filterXField;
  851.     floatSliderGrp -edit -enable $useMultiPixelFilter filterYField;
  852.  
  853.     // Now dim out items that are not applicable,
  854.     // based on the current settings
  855.  
  856.     if ($edgeAA == 3) { // Low
  857.         checkBoxGrp -edit -enable false pixelCheck;
  858.         optionMenuGrp -edit -enable false pixelFilterMenu;
  859.         floatSliderGrp -edit -enable false filterXField;
  860.         floatSliderGrp -edit -enable false filterYField;
  861.         floatSliderGrp -edit -enable false contrastRedField;
  862.         floatSliderGrp -edit -enable false contrastGreenField;
  863.         floatSliderGrp -edit -enable false contrastBlueField;
  864.         intSliderGrp -edit -enable false maxShadingSamplesField;
  865.         intSliderGrp -edit -enable ($useBlur && !$blur2d) visSamplesField;
  866.         intSliderGrp -edit -enable false maxVisSamplesField;
  867.     } else if ($edgeAA == 2) { // Medium
  868.         checkBoxGrp -edit -enable false pixelCheck;
  869.         optionMenuGrp -edit -enable false pixelFilterMenu;
  870.         floatSliderGrp -edit -enable false filterXField;
  871.         floatSliderGrp -edit -enable false filterYField;
  872.         floatSliderGrp -edit -enable false contrastRedField;
  873.         floatSliderGrp -edit -enable false contrastGreenField;
  874.         floatSliderGrp -edit -enable false contrastBlueField;
  875.         intSliderGrp -edit -enable false maxShadingSamplesField;
  876.         intSliderGrp -edit -enable ($useBlur && !$blur2d) visSamplesField;
  877.         intSliderGrp -edit -enable false maxVisSamplesField;
  878.     } else if ($edgeAA == 1) { // High
  879.         $enableMultiPixelFilter = true;
  880.         floatSliderGrp -edit -enable false contrastRedField;
  881.         floatSliderGrp -edit -enable false contrastGreenField;
  882.         floatSliderGrp -edit -enable false contrastBlueField;
  883.         intSliderGrp -edit -enable false maxShadingSamplesField;
  884.         intSliderGrp -edit -enable ($useBlur && !$blur2d) visSamplesField;
  885.         intSliderGrp -edit -enable false maxVisSamplesField;
  886.     } else if ($edgeAA == 0) { // Highest
  887.         $enableMultiPixelFilter = true;
  888.         floatSliderGrp -edit -enable true contrastRedField;
  889.         floatSliderGrp -edit -enable true contrastGreenField;
  890.         floatSliderGrp -edit -enable true contrastBlueField;
  891.         intSliderGrp -edit -enable true maxShadingSamplesField;
  892.         intSliderGrp -edit -enable ($useBlur && !$blur2d) visSamplesField;
  893.         intSliderGrp -edit -enable ($useBlur && !$blur2d) maxVisSamplesField;
  894.     }
  895.     if ($enableMultiPixelFilter) {
  896.         $enableFilterAttrs = `getAttr ($rendQual[0] + ".useMultiPixelFilter")`;
  897.     }
  898.     checkBoxGrp -edit -enable $enableMultiPixelFilter pixelCheck;
  899.     optionMenuGrp -edit -enable $enableFilterAttrs pixelFilterMenu;
  900.     floatSliderGrp -edit -enable $enableFilterAttrs filterXField;
  901.     floatSliderGrp -edit -enable $enableFilterAttrs filterYField;
  902. }
  903.  
  904. global proc updateMotionBlur ()
  905. //
  906. //  Procedure Name:
  907. //      updateMotionBlur
  908. //
  909. //  Description:
  910. //      Gets the real values from the nodes and sets the UI based
  911. //        on these values.  This procedure updates all of the motion
  912. //        blur values.
  913. //
  914. { 
  915.     int $useBlur = `getAttr defaultRenderGlobals.motionBlur`;
  916.     checkBoxGrp -edit -v1 $useBlur blurCheck;
  917.  
  918.     int $blur2d = (`getAttr defaultRenderGlobals.motionBlurType` == 0);
  919.     if ($blur2d) {
  920.         radioButtonGrp -edit -select 1 blurButton1;
  921.     } else {
  922.         radioButtonGrp -edit -select 1 blurButton2;
  923.     }
  924.  
  925.     radioButtonGrp -edit -enable $useBlur blurButton1;
  926.     radioButtonGrp -edit -enable $useBlur blurButton2;
  927.  
  928.     int $keepMotionVector = (`getAttr defaultRenderGlobals.keepMotionVector` == 1);
  929.     if ($useBlur && $blur2d && $keepMotionVector) {
  930.         global string $imgExt[];  // This is the actual file extension
  931.         global int $imgExtNum[];  // This is the corresponding internal value
  932.  
  933.         string $imageFormatExt = "";
  934.  
  935.         int $imageFormatNum = `getAttr defaultRenderGlobals.imageFormat`;
  936.  
  937.         // Get the corresponding imgExt for this imageFormat.
  938.  
  939.         for ($i = 0; $i < size($imgExtNum); $i += 1) {
  940.             if ($imageFormatNum == $imgExtNum[$i]) {
  941.                 $imageFormatExt = $imgExt[$i];
  942.                 break;
  943.             }
  944.         }
  945.  
  946.         // Check if the image format is not IFF.
  947.         //
  948.         // Note: there are two IFF image types. One for 8 bit images
  949.         // and one for 16 bit images. They both have an imgExt of iff.
  950.  
  951.         if ($imageFormatExt != "iff" ) {
  952.             warning
  953.                 ("Non-IFF image formats are not supported when writing"+
  954.                  " 2D motion vectors; setting image format to IFF");
  955.  
  956.             // Set globals imageFormat to Maya IFF
  957.             setAttr defaultRenderGlobals.imageFormat 7;
  958.         }
  959.     }
  960.  
  961.     floatFieldGrp -edit
  962.         -v1 `getAttr defaultRenderGlobals.motionBlurByFrame`
  963.         -enable $useBlur
  964.         blurFrameField;
  965.  
  966.     floatSliderGrp -edit
  967.         -v `getAttr defaultRenderGlobals.blurLength`
  968.         -enable ($useBlur && $blur2d)
  969.         blurLengthField;
  970.  
  971.     floatSliderGrp -edit
  972.         -v `getAttr defaultRenderGlobals.blurSharpness`
  973.         -enable ($useBlur && $blur2d)
  974.         blurSharpField;
  975.  
  976.     intFieldGrp -edit
  977.         -v1 `getAttr defaultRenderGlobals.smoothValue`
  978.         -enable ($useBlur && $blur2d)
  979.         blurSmoothField;
  980.  
  981.     int $smoothColor = `getAttr defaultRenderGlobals.smoothColor`;
  982.     radioButtonGrp -edit
  983.         -enable ($useBlur && $blur2d)
  984.         -select ($smoothColor + 1)
  985.         blurSmoothRadio;
  986.  
  987.     checkBoxGrp -edit
  988.         -v1 `getAttr defaultRenderGlobals.keepMotionVector`
  989.         -enable ($useBlur && $blur2d)
  990.         blurVectorCheck;
  991.  
  992.     int $useMemoryCap = `getAttr defaultRenderGlobals.useBlur2DMemoryCap`;
  993.     checkBoxGrp -edit
  994.         -v1 $useMemoryCap
  995.         -enable ($useBlur && $blur2d)
  996.         blurMemoryCapCheck;
  997.  
  998.     floatFieldGrp -edit
  999.         -v1 `getAttr defaultRenderGlobals.blur2DMemoryCap`
  1000.         -enable ($useBlur && $blur2d && $useMemoryCap)
  1001.         blurMemoryCapField;
  1002.  
  1003. }
  1004.  
  1005. global proc createMotionBlur (string $parent) 
  1006. //
  1007. //  Procedure Name:
  1008. //      createMotionBlur
  1009. //
  1010. //  Description:
  1011. //      Creates the UI in the "Motion Blur" expand/collapse section.
  1012. //
  1013. {
  1014.     setUITemplate -pushTemplate attributeEditorTemplate;
  1015.  
  1016.     setParent $parent;
  1017.     string $cName;
  1018.  
  1019.     // If the UI is created already then just update attribute values.
  1020.     if (`columnLayout -exists rgBlurLayout`) {
  1021.         updateMotionBlur;
  1022.         return;
  1023.     }
  1024.  
  1025.     columnLayout -adjustableColumn true rgBlurLayout;
  1026.        
  1027.         checkBoxGrp -numberOfCheckBoxes 1
  1028.             -label1 "Motion Blur"
  1029.             -cc "setAttr defaultRenderGlobals.motionBlur #1; updateMotionBlur; updateRenderQuality;"
  1030.             blurCheck;
  1031.         scriptJob -p $parent 
  1032.             -ac "defaultRenderGlobals.motionBlur" 
  1033.             "updateMotionBlur; updateRenderQuality;";
  1034.  
  1035.         radioButtonGrp -numberOfRadioButtons 1
  1036.             -label "Motion Blur Type"
  1037.             -label1 "2D" 
  1038.             -onc "setAttr defaultRenderGlobals.motionBlurType 0"
  1039.             blurButton1;
  1040.         radioButtonGrp -numberOfRadioButtons 1
  1041.             -shareCollection blurButton1
  1042.             -label ""
  1043.             -label1 "3D" 
  1044.             -onc "setAttr defaultRenderGlobals.motionBlurType 1"
  1045.             blurButton2;
  1046.         // Any time the motion blur type changes we also need to call
  1047.         // updateMotionBlur and updateRenderQuality. This is done through
  1048.         // a script job watching for an attribute change.
  1049.         scriptJob -p $parent 
  1050.             -ac "defaultRenderGlobals.motionBlurType" 
  1051.             "updateMotionBlur; updateRenderQuality;";
  1052.  
  1053.         $cName = `floatFieldGrp -label "Blur by Frame"
  1054.             -cc "setAttr defaultRenderGlobals.motionBlurByFrame #1"
  1055.             blurFrameField`;
  1056.         connectControl -index 2 $cName "defaultRenderGlobals.motionBlurByFrame";
  1057.  
  1058.         $cName = `floatSliderGrp -label "Blur Length"
  1059.             -fieldMaxValue 100
  1060.             -minValue 0
  1061.             -maxValue 30
  1062.             -cc "setAttr defaultRenderGlobals.blurLength #1"
  1063.             blurLengthField`;
  1064.         connectControl $cName "defaultRenderGlobals.blurLength";
  1065.  
  1066.         $cName = `floatSliderGrp -label "Blur Sharpness"
  1067.             -fieldMaxValue 100
  1068.             -minValue 0
  1069.             -maxValue 15
  1070.             -cc "setAttr defaultRenderGlobals.blurSharpness #1"
  1071.             blurSharpField`;
  1072.         connectControl $cName "defaultRenderGlobals.blurSharpness";
  1073.  
  1074.         $cName = `radioButtonGrp -label "Smooth"
  1075.             -numberOfRadioButtons 2
  1076.             -label1 "Alpha"
  1077.             -label2 "Color"
  1078.             -on1 "setAttr defaultRenderGlobals.smoothColor 0"
  1079.             -on2 "setAttr defaultRenderGlobals.smoothColor 1"
  1080.             blurSmoothRadio`;
  1081.         scriptJob -p $parent 
  1082.             -ac "defaultRenderGlobals.smoothColor" "updateMotionBlur";
  1083.  
  1084.         $cName = `intFieldGrp -label "Smooth Value"
  1085.             -cc "setAttr defaultRenderGlobals.smoothValue #1"
  1086.             blurSmoothField`;
  1087.         connectControl -index 2 $cName "defaultRenderGlobals.smoothValue";
  1088.  
  1089.         $cName = `checkBoxGrp -numberOfCheckBoxes 1
  1090.             -label1 "Keep Motion Vectors"
  1091.             -cc "setAttr defaultRenderGlobals.keepMotionVector #1"
  1092.             blurVectorCheck`;
  1093.         connectControl -index 2 $cName "defaultRenderGlobals.keepMotionVector";
  1094.  
  1095.         $cName = `checkBoxGrp -numberOfCheckBoxes 1
  1096.             -label1 "Use 2d Blur Memory Limit"
  1097.             -cc "setAttr defaultRenderGlobals.useBlur2DMemoryCap #1; updateMotionBlur"
  1098.             blurMemoryCapCheck`;
  1099.         connectControl -index 2 $cName "defaultRenderGlobals.useBlur2DMemoryCap";
  1100.  
  1101.         $cName = `floatFieldGrp -label "2d Blur Memory Limit"  
  1102.             -extraLabel "MB" -cal 3 "left"
  1103.             -cc "setAttr defaultRenderGlobals.blur2DMemoryCap #1"
  1104.             blurMemoryCapField`;
  1105.         connectControl -index 2 $cName "defaultRenderGlobals.blur2DMemoryCap";
  1106.         
  1107.  
  1108.     setParent ..;
  1109.     setUITemplate -popTemplate;
  1110.  
  1111.     // Make sure the values are right
  1112.     updateMotionBlur;
  1113. }
  1114.  
  1115.  
  1116. global proc updateRenderOptions ()
  1117. //
  1118. //  Procedure Name:
  1119. //      updateRenderOptions
  1120. //
  1121. //  Description:
  1122. //      Gets the real values from the nodes and sets the UI based
  1123. //        on these values.  This procedure updates all of the options
  1124. //        values.
  1125. //
  1126. { 
  1127.  
  1128. //  How do we get the value for this?
  1129. //    textFieldButtonGrp -edit
  1130. //        fogField;
  1131.  
  1132.     string $pluginFormat = `getAttr defaultRenderGlobals.pluginFormat`;
  1133.     textFieldGrp -edit -text $pluginFormat
  1134.         plugInFormat;
  1135.     
  1136.     string $preRenderMel = `getAttr defaultRenderGlobals.preRenderMel`;
  1137.     textFieldGrp -edit -text $preRenderMel
  1138.         preRenderMel;
  1139.     
  1140.     string $postRenderMel = `getAttr defaultRenderGlobals.postRenderMel`;
  1141.     textFieldGrp -edit -text $postRenderMel
  1142.         postRenderMel;
  1143.  
  1144.     checkBoxGrp -edit
  1145.         -v1 `getAttr "defaultRenderGlobals.enableDepthMaps"`
  1146.         depthMapCheck;
  1147.  
  1148.     checkBoxGrp -edit
  1149.         -v1 `getAttr "defaultRenderGlobals.enableDefaultLight"`
  1150.         defaultLightCheck;
  1151.  
  1152.     checkBoxGrp -edit
  1153.         -v1 `getAttr "defaultRenderGlobals.ignoreFilmGate"`
  1154.         filmGateCheck;
  1155.  
  1156.     checkBoxGrp -edit
  1157.         -v1 `getAttr "defaultRenderGlobals.clipFinalShadedColor"`
  1158.         clipCheck;
  1159.  
  1160.     checkBoxGrp -edit
  1161.         -v1 `getAttr "defaultRenderGlobals.jitterFinalColor"`
  1162.         jitterColor;
  1163.  
  1164.     checkBoxGrp -edit
  1165.         -v1 `getAttr "defaultRenderGlobals.composite"`
  1166.         compCheck;
  1167.  
  1168.     if (`isTrue MayaCreatorExists`) {
  1169.         checkBoxGrp -edit
  1170.             -v1 `getAttr "defaultRenderGlobals.applyFogInPost"`
  1171.             applyFogInPostCheck;
  1172.  
  1173.         intFieldGrp -edit
  1174.             -v1 `getAttr "defaultRenderGlobals.postFogBlur"`
  1175.             postFogBlurField;
  1176.     }
  1177.  
  1178.     checkBoxGrp -edit
  1179.         -v1 `getAttr "defaultRenderGlobals.shadowsObeyLightLinking"`
  1180.         shadowLightLinkCheck;
  1181.         
  1182.     floatFieldGrp -edit
  1183.         -v1 `getAttr "defaultRenderGlobals.compositeThreshold"`
  1184.         -enable `checkBoxGrp -q -v1 compCheck`
  1185.         compValueField;
  1186.  
  1187.     floatFieldGrp -edit
  1188.         -v1 `getAttr "defaultRenderGlobals.gammaCorrection"`
  1189.         gammaField;
  1190. }
  1191.  
  1192.  
  1193. //==================================================================
  1194. //
  1195. // Starting the data changing section
  1196. //
  1197. //==================================================================
  1198.  
  1199.  
  1200. global proc changeFileName ()
  1201. //
  1202. //  Procedure Name:
  1203. //      changeFileName
  1204. //
  1205. //  Description:
  1206. //        This procedure is called when the user changes the file
  1207. //        prefix.  It sets the internal representation of the prefix
  1208. //        and then updates the example to show the changes.
  1209. //
  1210. {
  1211.     string $prefix = `textFieldGrp -query -text fileName`;
  1212.     if ($prefix != "(not set; using filename)"
  1213.             && validFileNamePrefix($prefix)) {
  1214.         string $globalsAttr = "defaultRenderGlobals.imageFilePrefix";
  1215.         setAttr $globalsAttr -type "string" $prefix;
  1216.     }
  1217.  
  1218.     updateImageFile;
  1219.     updateFileOutputFeedback;
  1220. }
  1221.  
  1222. global proc changeExtension ()
  1223. //
  1224. //  Procedure Name:
  1225. //      changeExtension
  1226. //
  1227. //  Description:
  1228. //        This procedure is called when the user changes the format
  1229. //        of the file extension.  It sets the internal representation 
  1230. //        and then updates the example to show the changes.
  1231. //
  1232. //    Note:
  1233. //        Although the user sees only one control to change the
  1234. //        extension, it actually affects more than one value.
  1235. //
  1236. {
  1237.     global string $imgExt[];  // This is the actual file extension
  1238.     global int $imgExtNum[];  // This is the corresponding internal value
  1239.  
  1240.     int $item = `optionMenuGrp -q -sl extMenu`;
  1241.     int $ext = `optionMenuGrp -q -sl imageMenu` - 1; 
  1242.     int $multiframe = multiframeFormat($imgExt[$ext]);
  1243.     
  1244.     // print ("changeExtension to " + $ext + " " + $imgExt[$ext] + "\nmultiframe " + $multiframe + "\n" );
  1245.     {
  1246.         //
  1247.         // "name"
  1248.         //
  1249.         if ($item == 1) {
  1250.             // Animation off
  1251.             setAttr defaultRenderGlobals.animation 0;
  1252.             // No image file format type        
  1253.             setAttr defaultRenderGlobals.outFormatControl 1;    
  1254.             setAttr "defaultRenderGlobals.periodInExt" 1;
  1255.         //
  1256.         // "name.ext"
  1257.         //        
  1258.         } else if ($item == 2) {
  1259.             // Animation off
  1260.             setAttr defaultRenderGlobals.animation 0;            
  1261.             if (`checkBoxGrp -q -v1 imageCheckBox`) {
  1262.                 // Override image file format type
  1263.                 setAttr defaultRenderGlobals.outFormatControl 2;  
  1264.             } else {
  1265.                 // Standard image file format type
  1266.                 setAttr defaultRenderGlobals.outFormatControl 0;    
  1267.             }
  1268.             setAttr "defaultRenderGlobals.periodInExt" 1;
  1269.         //
  1270.         // "name.#.ext"
  1271.         //
  1272.         } else if ($item == 3) {
  1273.             // Animation on
  1274.             setAttr defaultRenderGlobals.animation 1; 
  1275.             if (`checkBoxGrp -q -v1 imageCheckBox`) {
  1276.                 // Override image file format type
  1277.                 setAttr defaultRenderGlobals.outFormatControl 2;  
  1278.             } else {
  1279.                 // Standard image file format type
  1280.                 setAttr defaultRenderGlobals.outFormatControl 0;    
  1281.             }
  1282.             setAttr "defaultRenderGlobals.putFrameBeforeExt" 1;
  1283.             setAttr "defaultRenderGlobals.periodInExt" 1;
  1284.         //
  1285.         // "name.ext.#"
  1286.         //
  1287.         } else if ($item == 4) {
  1288.             // Animation on
  1289.             setAttr defaultRenderGlobals.animation 1;
  1290.             if (`checkBoxGrp -q -v1 imageCheckBox`) {
  1291.                 // Override image file format type
  1292.                 setAttr defaultRenderGlobals.outFormatControl 2;  
  1293.             } else {
  1294.                 // Standard image file format type
  1295.                 setAttr defaultRenderGlobals.outFormatControl 0;    
  1296.             }
  1297.             setAttr "defaultRenderGlobals.putFrameBeforeExt" 0;
  1298.             setAttr "defaultRenderGlobals.periodInExt" 1;
  1299.         //
  1300.         // "name.#"
  1301.         //
  1302.         } else if ($item == 5) {
  1303.             // Animation on
  1304.             setAttr defaultRenderGlobals.animation 1;
  1305.             // No image file format type
  1306.             setAttr defaultRenderGlobals.outFormatControl 1;
  1307.             setAttr "defaultRenderGlobals.periodInExt" 1;
  1308.         //
  1309.         // "name#.ext"
  1310.         //
  1311.         } else if ($item == 6) {
  1312.             // Animation on
  1313.             setAttr defaultRenderGlobals.animation 1;
  1314.             if (`checkBoxGrp -q -v1 imageCheckBox`) {
  1315.                 // Override image file format type
  1316.                 setAttr defaultRenderGlobals.outFormatControl 2;
  1317.             } else {
  1318.                 // Standard image file format type
  1319.                 setAttr defaultRenderGlobals.outFormatControl 0;
  1320.             }
  1321.             setAttr "defaultRenderGlobals.putFrameBeforeExt" 1;
  1322.             setAttr "defaultRenderGlobals.periodInExt" 0;
  1323.         }
  1324.     }
  1325.  
  1326.     updateFrames;
  1327.     updateExtOptions;
  1328.     updateFileOutputFeedback;
  1329.  
  1330.     // Also update the main render window if it exists.
  1331.     if (`exists updateMainRenderMenu`) {
  1332.         updateMainRenderMenu();
  1333.     }
  1334.     // And the batch render window    
  1335.     if (`exists updateBatchRenderWindowTitle`) {
  1336.         updateBatchRenderWindowTitle();
  1337.     }
  1338. }
  1339.  
  1340. global proc changeImageFormat ()
  1341. //
  1342. //  Procedure Name:
  1343. //      changeImageFormat
  1344. //
  1345. //  Description:
  1346. //        This procedure is called when the user changes the type of 
  1347. //        image that will be written out.  It sets the internal 
  1348. //        representation and then updates the example to show the changes.
  1349. //
  1350. {
  1351.     global string $imgExt[];  // This is the actual file extension
  1352.     global int $imgExtNum[];  // This is the corresponding internal value
  1353.  
  1354.     int $item = `optionMenuGrp -q -sl imageMenu` - 1; 
  1355.     setAttr defaultRenderGlobals.imageFormat $imgExtNum[$item];
  1356.     updateFileOutputFeedback;
  1357.  
  1358.     // Check if the image format is IFF.
  1359.     //
  1360.     // Note: there are two IFF image types. One for 8 bit images
  1361.     // and one for 16 bit images. They both have an imgExt of iff.
  1362.  
  1363.     if ($imgExt[$item] != "iff") {
  1364.         int $useBlur = `getAttr defaultRenderGlobals.motionBlur`;
  1365.         int $blur2d = (`getAttr defaultRenderGlobals.motionBlurType` == 0);
  1366.         int $keepMotionVector = (`getAttr defaultRenderGlobals.keepMotionVector` == 1);
  1367.         if ($useBlur && $blur2d && $keepMotionVector) {
  1368.             warning
  1369.                 ("Non-IFF image formats are not supported when writing"+
  1370.                  " 2D motion vectors; setting image format to IFF");
  1371.  
  1372.             // Set globals imageFormat to Maya IFF
  1373.             setAttr defaultRenderGlobals.imageFormat 7;
  1374.         }
  1375.     }
  1376.  
  1377.     $item = `optionMenuGrp -q -sl imageMenu` - 1; 
  1378.     int $multiframe = multiframeFormat($imgExt[$item]);
  1379.  
  1380.     if ( $multiframe )
  1381.     {
  1382.         setAttr defaultRenderGlobals.animation 1;
  1383.     }
  1384.  
  1385.     updateFrames;
  1386.     updateExtOptions;
  1387.     updateFileOutputFeedback;
  1388.  
  1389.     // Also update the main render window if it exists.
  1390.     if (`exists updateMainRenderMenu`) {
  1391.         updateMainRenderMenu();
  1392.     }
  1393.     // And the batch render window    
  1394.     if (`exists updateBatchRenderWindowTitle`) {
  1395.         updateBatchRenderWindowTitle();
  1396.     }
  1397. }
  1398.  
  1399. global proc changeRenderObj ()
  1400. //
  1401. //  Procedure Name:
  1402. //      changeRenderObj
  1403. //
  1404. //  Description:
  1405. //        This procedure is called when the user changes the rendered 
  1406. //        objects.  It sets the internal representation.
  1407. //
  1408. {
  1409.     int $item = `optionMenuGrp -q -sl renderObjMenu`;
  1410.     if ($item == 1)
  1411.         setAttr defaultRenderGlobals.renderAll 1;
  1412.     else
  1413.         setAttr defaultRenderGlobals.renderAll 0;
  1414. }
  1415.  
  1416. global proc updateCameraAttrs ()
  1417. //
  1418. //  Procedure Name:
  1419. //      updateCameraAttrs
  1420. //
  1421. //  Description:
  1422. //        This procedure is called when the user changes attributes affecting
  1423. //        a camera.  It updates the corresponding attributes on the camera.
  1424. //
  1425. {
  1426.     int $camIndex = `optionMenuGrp -q -sl cameraMenu` - 1;
  1427.     string $allCameras[] = `ls -ca`;
  1428.     string $whichCamera = $allCameras[$camIndex];
  1429.     setAttr ($whichCamera + ".image") `checkBoxGrp -q -v1 rgbChannel`;
  1430.     setAttr ($whichCamera + ".mask") `checkBoxGrp -q -v1 alphaChannel`;
  1431.     setAttr ($whichCamera + ".depth") `checkBoxGrp -q -v1 depthChannel`;
  1432. }
  1433.  
  1434. global proc switchCamera ()
  1435. //
  1436. //  Procedure Name:
  1437. //      switchCamera
  1438. //
  1439. //  Description:
  1440. //        This procedure is called when the user changes the camera
  1441. //        that will be rendered.
  1442. //        It updates the controls for the new camera
  1443. //
  1444. {
  1445.     //
  1446.     // First count how many renderable cameras exist
  1447.     //
  1448.     string $allCameras[] = `ls -ca`;
  1449.     int $numRenderable = 0;
  1450.     for ($i = 0; $i < size($allCameras); $i++) {
  1451.         if (`getAttr ($allCameras[$i] + ".renderable")`) {
  1452.             $numRenderable++;
  1453.         }
  1454.     }
  1455.     int $camIndex = `optionMenuGrp -q -sl cameraMenu` - 1;
  1456.     if ($numRenderable < 2) {
  1457.         for ($i = 0; $i < size($allCameras); $i++) {
  1458.             if ($i == $camIndex) {
  1459.                 setAttr ($allCameras[$i] + ".renderable") 1;
  1460.             } else {
  1461.                 setAttr ($allCameras[$i] + ".renderable") 0;
  1462.             }
  1463.         }
  1464.     }
  1465.  
  1466.     string $whichCamera = $allCameras[$camIndex];
  1467.     checkBoxGrp -edit -v1 `getAttr ($whichCamera + ".image")` rgbChannel;
  1468.     checkBoxGrp -edit -v1 `getAttr ($whichCamera + ".mask")` alphaChannel;
  1469.     checkBoxGrp -edit -v1 `getAttr ($whichCamera + ".depth")` depthChannel;
  1470.     updateFileOutputFeedback;
  1471.  
  1472.     // Fix for 160069. The mental ray renderer and the Maya renderer
  1473.     // use the same renderable camera, so the mental ray render globals and
  1474.     // the Maya render globals must be kept in sync when the renderable camera
  1475.     // changes. The following code causes the attribute editor to be 
  1476.     // refreshed, just in case it contains the mental ray render globals.
  1477.     //
  1478.     global string $gAEFocusNode;
  1479.     updateAE($gAEFocusNode);
  1480. }
  1481.  
  1482. global proc changeCustomExtensionCheck ()
  1483. //
  1484. //  Procedure Name:
  1485. //      changeCustomExtensionCheck
  1486. //
  1487. //  Description:
  1488. //        This procedure is called when the user turns the custom 
  1489. //        extension on or off.  It sets the internal representation 
  1490. //        and then updates the example to show the changes.
  1491. //
  1492. {
  1493.     int $isOn = `checkBoxGrp -q -v1 imageCheckBox`;
  1494.     if ($isOn) {
  1495.         setAttr defaultRenderGlobals.outFormatControl 2;
  1496.     } else {
  1497.         // We have to figure out if there should be an extension
  1498.         // at all or not. 
  1499.         int $item = `optionMenuGrp -q -sl extMenu`;
  1500.         if ($item == 1 || $item == 5) {
  1501.             setAttr defaultRenderGlobals.outFormatControl 1;
  1502.         } else {
  1503.             setAttr defaultRenderGlobals.outFormatControl 0;
  1504.         }
  1505.     }   
  1506.  
  1507.     updateExtOptions;
  1508.     updateFileOutputFeedback;
  1509. }
  1510.  
  1511. global proc changeCustomExtensionName ()
  1512. //
  1513. //  Procedure Name:
  1514. //      changeCustomExtensionName
  1515. //
  1516. //  Description:
  1517. //        This procedure is called when the user specifies a custom 
  1518. //        extension.  It sets the internal representation 
  1519. //        and then updates the example to show the changes.
  1520. //
  1521. {
  1522.     setAttr -type "string" "defaultRenderGlobals.outFormatExt" `textFieldGrp -q -text userExt`;
  1523.     updateExtOptions;
  1524.     updateFileOutputFeedback;
  1525. }
  1526.  
  1527. global proc changeFrameExtension ()
  1528. //
  1529. //  Procedure Name:
  1530. //      changeFrameExtension
  1531. //
  1532. //  Description:
  1533. //        This procedure is called when the user overrides the 
  1534. //        frame numbers with new output numbers.  It sets the internal 
  1535. //        representation and then updates the example to show the changes.
  1536. //
  1537. {
  1538.     int $newValue = `intFieldGrp -q -v1 frameStartOverride`;
  1539.     if ($newValue < 0) {
  1540.         $newValue = 0;
  1541.         intFieldGrp -edit -v1 $newValue frameStartOverride;
  1542.         catch (warning("Value cannot be negative."));
  1543.     }
  1544.     setAttr "defaultRenderGlobals.startExtension" $newValue;
  1545.  
  1546.     $newValue = `intFieldGrp -q -v1 frameByOverride`;
  1547.     if ($newValue < 0) {
  1548.         $newValue = 0;
  1549.         intFieldGrp -edit -v1 $newValue frameByOverride;
  1550.         catch (warning("Value cannot be negative."));
  1551.     }
  1552.     setAttr "defaultRenderGlobals.byExtension" $newValue;
  1553.  
  1554.     updateFileOutputFeedback;
  1555. }
  1556.  
  1557. global proc changeFieldOptions ()
  1558. //
  1559. //  Procedure Name:
  1560. //      changeFieldOptions
  1561. //
  1562. //  Description:
  1563. //        This procedure is called when the user changes any of the 
  1564. //        values for fields.  It sets the internal representation
  1565. //        and then updates the example to show the changes.
  1566. //
  1567. {
  1568.     // Note that we stored the fields values internally different
  1569.     // from what's presented in the menu.  That is why the below
  1570.     // convoluted case statement.  Sorry - see 123444.
  1571.     int $realFieldsValue = (`optionMenuGrp -q -sl fieldMenu` - 1);
  1572.     switch ($realFieldsValue) {
  1573.         case 0:
  1574.             setAttr "defaultResolution.fields" 0;
  1575.             break;
  1576.         case 1:
  1577.         case 2:
  1578.             setAttr "defaultResolution.fields" ($realFieldsValue + 2);
  1579.             break;
  1580.         case 3:
  1581.         case 4:
  1582.             setAttr "defaultResolution.fields" ($realFieldsValue - 2);
  1583.             break;
  1584.     }
  1585.  
  1586.  
  1587.     int $whichDominance = `optionMenuGrp -q -sl fieldDominanceMenu`;
  1588.     if ($whichDominance == 1) {
  1589.         setAttr "defaultResolution.oddFieldFirst" true;
  1590.     } else {
  1591.         setAttr "defaultResolution.oddFieldFirst" false;
  1592.     }
  1593.     setAttr "defaultResolution.zerothScanline"
  1594.         (`radioButtonGrp -q -sl scanlineButtons` -1);
  1595.     
  1596.     if (`radioButtonGrp -q -sl fieldButton1`) {
  1597.         setAttr "defaultRenderGlobals.fieldExtControl" 1;
  1598.     } else if (`radioButtonGrp -q -sl fieldButton2`) {
  1599.         setAttr "defaultRenderGlobals.fieldExtControl" 0; 
  1600.     } else {
  1601.         setAttr "defaultRenderGlobals.fieldExtControl" 2; 
  1602.     }
  1603.     
  1604.     string $test = `textFieldGrp -q -text oddFieldExt`;
  1605.     if (size($test) > 1) {
  1606.         catch (error ("Field extensions must be a single character."));
  1607.     } else {
  1608.         setAttr -type "string" "defaultRenderGlobals.oddFieldExt" $test;
  1609.     }
  1610.     
  1611.     $test = `textFieldGrp -q -text evenFieldExt`;
  1612.     if (size($test) > 1) {
  1613.         catch (error ("Field extensions must be a single character."));
  1614.     } else {
  1615.         setAttr -type "string" "defaultRenderGlobals.evenFieldExt"  $test;
  1616.     }
  1617.  
  1618.     updateFieldOptions;
  1619.     updateFileOutputFeedback;
  1620. }
  1621.  
  1622. global proc changeResolution ()
  1623. //
  1624. //  Procedure Name:
  1625. //      changeResolution
  1626. //
  1627. //  Description:
  1628. //        This procedure is called when the user selects a different
  1629. //        resolution.  It sets the internal representation
  1630. //        and then updates the example to show the changes.
  1631. //
  1632. {
  1633.     global string   $gImageFormatData[];
  1634.     global string   $gUserImageFormatData[];
  1635.     int        $numResolutionPresets = size($gImageFormatData);
  1636.     int        $numUserResolutionPresets = size($gUserImageFormatData);
  1637.     string $allResNodes[] = `ls -type resolution`;
  1638.     int        $numResolutionNodePresets = size($allResNodes) - 1;
  1639.     string    $tokens[];
  1640.     int        $resItem = `optionMenuGrp -q -sl resolutionMenu`; 
  1641.     int        $resWidth;
  1642.     int        $resHeight;
  1643.     float    $resAspect;
  1644.     string    $item;
  1645.  
  1646.     // Item #1 is Custom, which doesn't change the fields
  1647.     // We subtract _2_ from $resItem below: 1 because we're
  1648.     // skipping the first item (Custom) in the list, and 1
  1649.     // because the optionMenu items are numbered starting at 1,
  1650.     // but our list in $gImageFormatData is indexed starting at 0.
  1651.     //
  1652.     if ($resItem > 1) {
  1653.         if ($resItem > ($numResolutionPresets + 1)) {
  1654.             if ($resItem
  1655.                     > ($numResolutionPresets + $numUserResolutionPresets + 1)) {
  1656.                 // It's one of the user-defined resolution nodes' presets
  1657.                 string $resNodeName = $allResNodes[$resItem
  1658.                                                 - $numResolutionPresets
  1659.                                                 - $numUserResolutionPresets
  1660.                                                 - 1];
  1661.                 $resWidth = `getAttr ($resNodeName + ".width")`;
  1662.                 $resHeight = `getAttr ($resNodeName + ".height")`;
  1663.                 $resAspect = `getAttr ($resNodeName + ".deviceAspectRatio")`;
  1664.             } else {
  1665.                 // It's one of the user-defined resolution presets
  1666.                 $item = $gUserImageFormatData[$resItem
  1667.                     - $numResolutionPresets - 2];
  1668.                 int        $numTokens = tokenize($item, $tokens);
  1669.                 $resWidth = $tokens[1];
  1670.                 $resHeight = $tokens[2];
  1671.                 $resAspect = $tokens[3];
  1672.             }
  1673.         } else {
  1674.             // It's one of the built-in resolution presets
  1675.             $item = $gImageFormatData[$resItem - 2];
  1676.             int        $numTokens = tokenize($item, $tokens);
  1677.             $resWidth = $tokens[1];
  1678.             $resHeight = $tokens[2];
  1679.             $resAspect = $tokens[3];
  1680.         }
  1681.         setAttr "defaultResolution.width" $resWidth;
  1682.         setAttr "defaultResolution.height" $resHeight;
  1683.         setAttr "defaultResolution.deviceAspectRatio" $resAspect;
  1684.         setAttr "defaultResolution.lockDeviceAspectRatio" 1;
  1685.  
  1686.         // Set the proper field ordering if PAL or NTSC.
  1687.         if (`getAttr defaultResolution.height` == 576) { // PAL
  1688.             setAttr "defaultResolution.oddFieldFirst" 0;
  1689.             if (`columnLayout -exists rgFieldLayout`) updateFieldOptions();
  1690.         } else if (`getAttr defaultResolution.height` == 486) { // NTSC
  1691.             setAttr "defaultResolution.oddFieldFirst" 1;
  1692.             if (`columnLayout -exists rgFieldLayout`) updateFieldOptions();
  1693.         }
  1694.     }
  1695.  
  1696.     updateResolution;
  1697. }
  1698.  
  1699. global proc changeAspectLockWidth ()
  1700. //
  1701. //  Procedure Name:
  1702. //      changeAspectLockWidth
  1703. //
  1704. //  Description:
  1705. //        This procedure is called when the user changes the
  1706. //        resolution width.  It sets the internal representation
  1707. //        then looks at the ratio lock etc and changes any other 
  1708. //        values that rely on it. 
  1709. //
  1710. {
  1711.     int $requestedWidth = `intFieldGrp -q -v1 resWidth`;
  1712.     int $isMayaEvalVersion = `about -ev`;
  1713.     int $kPLEMaxX = 1024;
  1714.     int $kPLEMaxY =  768;
  1715.     if ( $isMayaEvalVersion ) {
  1716.         if( $requestedWidth > $kPLEMaxX ) {
  1717.             warning( "Image resolution is limited to "+$kPLEMaxX+"x"+$kPLEMaxY+" pixels for the Maya Personal Learning Edition" );
  1718.             $requestedWidth = $kPLEMaxX;
  1719.         }
  1720.         if( `getAttr defaultResolution.aspectLock` ) {
  1721.             float $aspect = `getAttr defaultResolution.pixelAspect`;
  1722.             if ( $aspect > 0.0 ){
  1723.                 int $rez = $aspect * $requestedWidth;
  1724.                 int $oldrez = `getAttr defaultResolution.height`;
  1725.                 if ($rez <= $kPLEMaxY) {
  1726.                     if ($rez - $oldrez > 1 || $oldrez - $rez > 1) {
  1727.                         setAttr defaultResolution.height $rez;
  1728.                     }
  1729.                 } else {
  1730.                     intFieldGrp -e -v1 $kPLEMaxY resHeight;
  1731.                     changeAspectLockHeight;
  1732.                     return;
  1733.                 }
  1734.             }
  1735.         }
  1736.     }
  1737.  
  1738.     if ($requestedWidth < 2) {
  1739.         warning "Width must be at least 2 pixels";
  1740.         $requestedWidth = 2;
  1741.     }
  1742.  
  1743.     setAttr defaultResolution.width $requestedWidth;
  1744.     optionMenuGrp -edit -sl 1 resolutionMenu;
  1745.     checkAspectLockWidth "defaultResolution";
  1746.  
  1747.     // Update the values
  1748.     updateResolution;
  1749. }
  1750.  
  1751. global proc changeAspectLockHeight ()
  1752. //
  1753. //  Procedure Name:
  1754. //      changeAspectLockHeight
  1755. //
  1756. //  Description:
  1757. //        This procedure is called when the user changes the
  1758. //        resolution width.  It sets the internal representation
  1759. //        then looks at the ratio lock etc and changes any other 
  1760. //        values that rely on it. 
  1761. //
  1762. {
  1763.     int $requestedHeight = `intFieldGrp -q -v1 resHeight`;
  1764.     int $isMayaEvalVersion = `about -ev`;
  1765.     int $kPLEMaxX = 1024;
  1766.     int $kPLEMaxY =  768;
  1767.     if ( $isMayaEvalVersion ) {
  1768.         if( $requestedHeight > $kPLEMaxY ) {
  1769.             warning( "Image resolution is limited to "+$kPLEMaxX+"x"+$kPLEMaxY+" pixels for the Maya Personal Learning Edition" );
  1770.             $requestedHeight = $kPLEMaxY;
  1771.         }
  1772.         if( `getAttr defaultResolution.aspectLock` ) {
  1773.             float $aspect = `getAttr defaultResolution.pixelAspect`;
  1774.             if ( $aspect > 0.0 ){
  1775.                 int $rez = $requestedHeight / $aspect;
  1776.                 int $oldrez = `getAttr defaultResolution.width`;
  1777.                 if ($rez <= $kPLEMaxX) {
  1778.                     if ($rez - $oldrez > 1 || $oldrez - $rez > 1) {
  1779.                         setAttr defaultResolution.width $rez;
  1780.                     }
  1781.                 } else {
  1782.                     intFieldGrp -e -v1 $kPLEMaxX resWidth;
  1783.                     changeAspectLockWidth;
  1784.                     return;
  1785.                 }
  1786.             }
  1787.         }
  1788.     }
  1789.  
  1790.     if ($requestedHeight < 2) {
  1791.         warning "Height must be at least 2 pixels";
  1792.         $requestedHeight = 2;
  1793.     }
  1794.  
  1795.     setAttr defaultResolution.height $requestedHeight;
  1796.     optionMenuGrp -edit -sl 1 resolutionMenu;
  1797.     checkAspectLockHeight "defaultResolution";
  1798.  
  1799.     // Set the proper field ordering if PAL or NTSC.
  1800.     if (`getAttr defaultResolution.height` == 576) { // PAL
  1801.         setAttr "defaultResolution.oddFieldFirst" 0;
  1802.         if (`columnLayout -exists rgFieldLayout`) updateFieldOptions();
  1803.     } else if (`getAttr defaultResolution.height` == 486) { // NTSC
  1804.         setAttr "defaultResolution.oddFieldFirst" 1;
  1805.         if (`columnLayout -exists rgFieldLayout`) updateFieldOptions();
  1806.     }
  1807.  
  1808.     // Update the values
  1809.     updateResolution;
  1810. }
  1811.  
  1812. //==================================================================
  1813. //
  1814. // Starting the UI creation section
  1815. //
  1816. //==================================================================
  1817.  
  1818. global proc createImageFile (string $parent) 
  1819. //
  1820. //  Procedure Name:
  1821. //      createImageFile
  1822. //
  1823. //  Description:
  1824. //      Creates the UI in the "Image File Output" expand/collapse section.
  1825. //        This section is always created so is treated differently
  1826. //        then the sections created when the tab is expanded.
  1827. //
  1828. {
  1829.     setUITemplate -pushTemplate attributeEditorTemplate;
  1830.  
  1831.     setParent $parent;
  1832.     string $cName;
  1833.     
  1834.     columnLayout -adjustableColumn true;
  1835.  
  1836.         textFieldGrp -label "File Name Prefix" -cc changeFileName fileName;
  1837.  
  1838.         // Extension ------------------------------------------------
  1839.  
  1840.         optionMenuGrp -label "Frame/Animation Ext" -cc changeExtension extMenu;
  1841.             menuItem -label "name (Single Frame)";
  1842.             menuItem -label "name.ext (Single Frame)";
  1843.             menuItem -label "name.#.ext";            
  1844.             menuItem -label "name.ext.#";    
  1845.             menuItem -label "name.#";    
  1846.             menuItem -label "name#.ext";
  1847.  
  1848.         // Frames numbers ------------------------------------------------
  1849.  
  1850.         floatFieldGrp -numberOfFields 1
  1851.             -label "Start Frame"
  1852.             -cc "setAttr defaultRenderGlobals.startFrame `floatFieldGrp -q -v1 startFrame`; updateFileOutputFeedback" 
  1853.             startFrame;
  1854.         scriptJob -p $parent 
  1855.             -ac "defaultRenderGlobals.startFrame" 
  1856.             "updateFrames; updateFileOutputFeedback;";
  1857.  
  1858.         floatFieldGrp -numberOfFields 1
  1859.             -label "End Frame"
  1860.             -cc "setAttr defaultRenderGlobals.endFrame `floatFieldGrp -q -v1 endFrame`; updateFileOutputFeedback" 
  1861.             endFrame;
  1862.         scriptJob -p $parent 
  1863.             -ac "defaultRenderGlobals.endFrame" 
  1864.             "updateFrames; updateFileOutputFeedback;";
  1865.  
  1866.         floatFieldGrp -numberOfFields 1
  1867.             -label "By Frame"
  1868.             -cc "setAttr defaultRenderGlobals.byFrameStep `floatFieldGrp -q -v1 frameStep`" 
  1869.             frameStep;
  1870.         scriptJob -p $parent 
  1871.             -ac "defaultRenderGlobals.byFrameStep" 
  1872.             "updateFrames; updateFileOutputFeedback;";
  1873.  
  1874.         intFieldGrp -numberOfFields 1
  1875.             -label "Frame Padding"
  1876.             -cc "setAttr defaultRenderGlobals.extensionPadding `intFieldGrp -q -v1 extPad`; updateFileOutputFeedback" 
  1877.             extPad;
  1878.         scriptJob -p $parent 
  1879.             -ac "defaultRenderGlobals.extensionPadding" 
  1880.             "updateFrames; updateFileOutputFeedback;";
  1881.     
  1882.         // Image Format ------------------------------------------------
  1883.  
  1884.         // These tables translate between the internal representation of the
  1885.         // image formats and the UI that is presented to the user.
  1886.         //
  1887.  
  1888.         // Fill up the above tables alphabetically.
  1889.         // NOTE !!!! WARNING !!!! NOTE !!!! WARNING !!!! NOTE !!!! WARNING !!!!
  1890.         // If you are changing one of the menuItem fields below or adding new ones or
  1891.         // whatever, be certain to also update the fields in the 'createImageFormats()'
  1892.         // procedure of createImageFormats.mel
  1893.  
  1894.         global string $imgExt[];
  1895.  
  1896.         if (size( $imgExt ) == 0) {
  1897.             // If the file format array has not been initialized yet, do so.
  1898.             // This routine may be called in dynPaintMenus.mel during the
  1899.             // file save for PFX canvas images.
  1900.             createImageFormats();
  1901.         }
  1902.  
  1903.            int $isMayaEvalVersion = `about -ev`;
  1904.  
  1905.         if ( $isMayaEvalVersion ) {
  1906.  
  1907.            if (`about -nt`) {
  1908.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1909.             menuItem -label "Alias PIX (als)";      //  $imgExt[0]  = "als";  $imgExtNum[0]  =  6;
  1910.             menuItem -label "AVI (avi)";            //  $imgExt[1]  = "avi";  $imgExtNum[1]  = 23;
  1911.             menuItem -label "Cineon (cin)";         //  $imgExt[2]  = "cin";  $imgExtNum[2]  = 11;
  1912.             menuItem -label "EPS (eps)";            //  $imgExt[3]  = "eps";  $imgExtNum[3]  =  9;
  1913.             menuItem -label "GIF (gif)";            //  $imgExt[4]  = "gif";  $imgExtNum[4]  =  0;
  1914.             menuItem -label "JPEG (jpeg)";          //  $imgExt[5]  = "jpeg"; $imgExtNum[5]  =  8;
  1915.             menuItem -label "Maya IFF (iff)";       //  $imgExt[6]  = "iff";  $imgExtNum[6]  =  7;
  1916.             menuItem -label "Quantel (yuv)";        //  $imgExt[7]  = "yuv";  $imgExtNum[8]  = 12;
  1917.             menuItem -label "RLA (rla)";            //  $imgExt[8]  = "rla";  $imgExtNum[9]  =  2;
  1918.             menuItem -label "SGI (sgi)";            //  $imgExt[9]  = "sgi";  $imgExtNum[10] =  5;
  1919.             menuItem -label "SoftImage (pic)";      //  $imgExt[10] = "pic";  $imgExtNum[12] =  1;
  1920.             menuItem -label "Targa (tga)";          //  $imgExt[11] = "tga";  $imgExtNum[13] = 19;
  1921.             menuItem -label "Tiff (tif)";           //  $imgExt[12] = "tif";  $imgExtNum[14] =  3;
  1922.             menuItem -label "Windows Bitmap (bmp)"; //  $imgExt[13] = "bmp";  $imgExtNum[16] = 20;
  1923.            } else if (`about -irix`)  {
  1924.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1925.             menuItem -label "Alias PIX (als)";        //  $imgExt[0]  = "als";  $imgExtNum[0]  =  6;
  1926.             menuItem -label "AVI (avi)";            //  $imgExt[1]  = "avi";  $imgExtNum[1]  = 23;
  1927.             menuItem -label "Cineon (cin)";            //  $imgExt[2]  = "cin";  $imgExtNum[2]  = 11;
  1928.             menuItem -label "EPS (eps)";            //  $imgExt[3]  = "eps";  $imgExtNum[3]  =  9;
  1929.             menuItem -label "GIF (gif)";            //  $imgExt[4]  = "gif";  $imgExtNum[4]  =  0;
  1930.             menuItem -label "JPEG (jpeg)";            //  $imgExt[5]  = "jpeg"; $imgExtNum[5]  =  8;
  1931.             menuItem -label "Maya IFF (iff)";          //  $imgExt[6]  = "iff";  $imgExtNum[6]  =  7;
  1932.             menuItem -label "Quantel (yuv)";        //  $imgExt[7]  = "yuv";  $imgExtNum[7]  = 12;
  1933.             menuItem -label "Quicktime (qt)";        //  $imgExt[8]  = "qt";   $imgExtNum[8]  = 22;
  1934.             menuItem -label "RLA (rla)";            //  $imgExt[9]  = "rla";  $imgExtNum[9]  =  2;
  1935.             menuItem -label "SGI (sgi)";            //  $imgExt[10] = "sgi";  $imgExtNum[10] =  5;
  1936.             menuItem -label "SGI Movie (mv)";        //  $imgExt[11] = "mv";   $imgExtNum[11] = 21;
  1937.             menuItem -label "SoftImage (pic)";        //  $imgExt[12] = "pic";  $imgExtNum[12] =  1;
  1938.             menuItem -label "Targa (tga)";            //  $imgExt[13] = "tga";  $imgExtNum[13] = 19;
  1939.             menuItem -label "Tiff (tif)";            //  $imgExt[14] = "tif";  $imgExtNum[14] =  3;
  1940.             menuItem -label "Windows Bitmap (bmp)";        //  $imgExt[15] = "bmp";  $imgExtNum[15] = 20; 
  1941.            } else if (`about -linux`)  {
  1942.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1943.             menuItem -label "Alias PIX (als)";        //  $imgExt[0]  = "als";  $imgExtNum[0]  =  6;
  1944.             menuItem -label "Cineon (cin)";            //  $imgExt[1]  = "cin";  $imgExtNum[1]  = 11;
  1945.             menuItem -label "EPS (eps)";            //  $imgExt[2]  = "eps";  $imgExtNum[2]  =  9;
  1946.             menuItem -label "GIF (gif)";            //  $imgExt[3]  = "gif";  $imgExtNum[3]  =  0;
  1947.             menuItem -label "JPEG (jpeg)";            //  $imgExt[4]  = "jpeg"; $imgExtNum[4]  =  8;
  1948.             menuItem -label "Maya IFF (iff)";          //  $imgExt[5]  = "iff";  $imgExtNum[5]  =  7;
  1949.             menuItem -label "Quantel (yuv)";        //  $imgExt[6]  = "yuv";  $imgExtNum[6]  = 12;
  1950.             menuItem -label "RLA (rla)";            //  $imgExt[7]  = "rla";  $imgExtNum[7]  =  2;
  1951.             menuItem -label "SGI (sgi)";            //  $imgExt[8]  = "sgi";  $imgExtNum[8]  =  5;
  1952.             menuItem -label "SoftImage (pic)";        //  $imgExt[9]  = "pic";  $imgExtNum[9]  =  1;
  1953.             menuItem -label "Targa (tga)";            //  $imgExt[10] = "tga";  $imgExtNum[10] = 19;
  1954.             menuItem -label "Tiff (tif)";            //  $imgExt[11] = "tif";  $imgExtNum[11] =  3;
  1955.             menuItem -label "Windows Bitmap (bmp)";        //  $imgExt[12] = "bmp";  $imgExtNum[12] = 20; 
  1956.            } else if ( `about -mac` ) {
  1957.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1958.             menuItem -label "JPEG (jpeg)";
  1959.             menuItem -label "Maya IFF (iff)";
  1960.             menuItem -label "MacPaint (pntg)";
  1961.             menuItem -label "Photoshop (ps)";
  1962.             menuItem -label "PNG (png)";
  1963.             menuItem -label "QuickDraw (pict)";
  1964.             menuItem -label "Quicktime Movie (qt)";
  1965.             menuItem -label "Quicktime Image (qtif)";
  1966.             menuItem -label "Silicon Graphics (sgi)";
  1967.             menuItem -label "Targa (tga)";
  1968.             menuItem -label "Tiff (tif)";
  1969.             menuItem -label "Windows Bitmap (bmp)";
  1970.            } else {
  1971.             warning "Unsupported platform in renderGlobalsWindow.mel";
  1972.            }
  1973.  
  1974.         } else {
  1975.  
  1976.         if (`about -nt`) {
  1977.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1978.             menuItem -label "Alias PIX (als)";      //  $imgExt[0]  = "als";  $imgExtNum[0]  = 6;
  1979.             menuItem -label "AVI (avi)";            //  $imgExt[1]  = "avi";  $imgExtNum[1]  = 23;
  1980.             menuItem -label "Cineon (cin)";         //  $imgExt[2]  = "cin";  $imgExtNum[2]  = 11;
  1981.             menuItem -label "EPS (eps)";            //  $imgExt[3]  = "eps";  $imgExtNum[3]  = 9;
  1982.             menuItem -label "GIF (gif)";            //  $imgExt[4]  = "gif";  $imgExtNum[4]  = 0;
  1983.             menuItem -label "JPEG (jpeg)";          //  $imgExt[5]  = "jpeg"; $imgExtNum[5]  = 8;
  1984.             menuItem -label "Maya IFF (iff)";       //  $imgExt[6]  = "iff";  $imgExtNum[6]  = 7;
  1985.             menuItem -label "Maya16 IFF (iff)";     //  $imgExt[7]  = "iff";  $imgExtNum[7]  = 10;
  1986.             menuItem -label "Quantel (yuv)";        //  $imgExt[8]  = "yuv";  $imgExtNum[8]  = 12;
  1987.             menuItem -label "RLA (rla)";            //  $imgExt[9]  = "rla";  $imgExtNum[9]  = 2;
  1988.             menuItem -label "SGI (sgi)";            //  $imgExt[10] = "sgi";  $imgExtNum[10]  = 5;
  1989.             menuItem -label "SGI16 (sgi)";          //  $imgExt[11] = "sgi";  $imgExtNum[11] = 13;
  1990.             menuItem -label "SoftImage (pic)";      //  $imgExt[12] = "pic";  $imgExtNum[12] = 1;
  1991.             menuItem -label "Targa (tga)";          //  $imgExt[13] = "tga";  $imgExtNum[13] = 19;
  1992.             menuItem -label "Tiff (tif)";           //  $imgExt[14] = "tif";  $imgExtNum[14] = 3;
  1993.             menuItem -label "Tiff16 (tif)";         //  $imgExt[15] = "tif";  $imgExtNum[15] = 4;
  1994.             menuItem -label "Windows Bitmap (bmp)"; //  $imgExt[16] = "bmp";  $imgExtNum[16] = 20;
  1995.         } else if (`about -irix`)  {
  1996.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  1997.             menuItem -label "Alias PIX (als)";        //  $imgExt[0]  = "als";  $imgExtNum[0]  = 6;
  1998.             menuItem -label "AVI (avi)";            //  $imgExt[1]  = "avi";  $imgExtNum[1]  = 23;
  1999.             menuItem -label "Cineon (cin)";            //  $imgExt[2]  = "cin";  $imgExtNum[2]  = 11;
  2000.             menuItem -label "EPS (eps)";            //  $imgExt[3]  = "eps";  $imgExtNum[3]  = 9;
  2001.             menuItem -label "GIF (gif)";            //  $imgExt[4]  = "gif";  $imgExtNum[4]  = 0;
  2002.             menuItem -label "JPEG (jpeg)";            //  $imgExt[5]  = "jpeg"; $imgExtNum[5]  = 8;
  2003.             menuItem -label "Maya IFF (iff)";          //  $imgExt[6]  = "iff";  $imgExtNum[6]  = 7;
  2004.             menuItem -label "Maya16 IFF (iff)";        //  $imgExt[7]  = "iff";  $imgExtNum[7]  = 10;
  2005.             menuItem -label "Quantel (yuv)";        //  $imgExt[8]  = "yuv";  $imgExtNum[8]  = 12;
  2006.             menuItem -label "Quicktime (qt)";        //  $imgExt[9]  = "qt";   $imgExtNum[9]  = 22;
  2007.             menuItem -label "RLA (rla)";            //  $imgExt[10]  = "rla"; $imgExtNum[10]  = 2;
  2008.             menuItem -label "SGI (sgi)";            //  $imgExt[11] = "sgi";  $imgExtNum[11]  = 5;
  2009.             menuItem -label "SGI16 (sgi)";            //  $imgExt[12] = "sgi";  $imgExtNum[12] = 13;
  2010.             menuItem -label "SGI Movie (mv)";        //  $imgExt[13] = "mv";   $imgExtNum[13] = 21;
  2011.             menuItem -label "SoftImage (pic)";        //  $imgExt[14] = "pic";  $imgExtNum[14] = 1;
  2012.             menuItem -label "Targa (tga)";            //  $imgExt[15] = "tga";  $imgExtNum[15] = 19;
  2013.             menuItem -label "Tiff (tif)";            //  $imgExt[16] = "tif";  $imgExtNum[16] = 3;
  2014.             menuItem -label "Tiff16 (tif)";            //  $imgExt[17] = "tif";  $imgExtNum[17] = 4;
  2015.             menuItem -label "Windows Bitmap (bmp)";    //  $imgExt[18] = "bmp";  $imgExtNum[18] = 20;
  2016.         } else if (`about -linux`)  {
  2017.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  2018.             menuItem -label "Alias PIX (als)";        //  $imgExt[0]  = "als";  $imgExtNum[0]  = 6;
  2019.             menuItem -label "Cineon (cin)";            //  $imgExt[1]  = "cin";  $imgExtNum[1]  = 11;
  2020.             menuItem -label "EPS (eps)";            //  $imgExt[2]  = "eps";  $imgExtNum[2]  = 9;
  2021.             menuItem -label "GIF (gif)";            //  $imgExt[3]  = "gif";  $imgExtNum[3]  = 0;
  2022.             menuItem -label "JPEG (jpeg)";            //  $imgExt[4]  = "jpeg"; $imgExtNum[4]  = 8;
  2023.             menuItem -label "Maya IFF (iff)";          //  $imgExt[5]  = "iff";  $imgExtNum[5]  = 7;
  2024.             menuItem -label "Maya16 IFF (iff)";        //  $imgExt[6]  = "iff";  $imgExtNum[6]  = 10;
  2025.             menuItem -label "Quantel (yuv)";        //  $imgExt[7]  = "yuv";  $imgExtNum[7]  = 12;
  2026.             menuItem -label "RLA (rla)";            //  $imgExt[8]  = "rla";  $imgExtNum[8]  = 2;
  2027.             menuItem -label "SGI (sgi)";            //  $imgExt[9] = "sgi";   $imgExtNum[9]  = 5;
  2028.             menuItem -label "SGI16 (sgi)";            //  $imgExt[10] = "sgi";  $imgExtNum[10] = 13;
  2029.             menuItem -label "SoftImage (pic)";        //  $imgExt[11] = "pic";  $imgExtNum[11] = 1;
  2030.             menuItem -label "Targa (tga)";            //  $imgExt[12] = "tga";  $imgExtNum[12] = 19;
  2031.             menuItem -label "Tiff (tif)";            //  $imgExt[13] = "tif";  $imgExtNum[13] = 3;
  2032.             menuItem -label "Tiff16 (tif)";            //  $imgExt[14] = "tif";  $imgExtNum[14] = 4;
  2033.             menuItem -label "Windows Bitmap (bmp)";    //  $imgExt[15] = "bmp";  $imgExtNum[15] = 20;
  2034.         } else if ( `about -mac` ) {
  2035.             optionMenuGrp -label "Image Format" -cc changeImageFormat imageMenu;
  2036.             menuItem -label "JPEG (jpeg)";            //    $imgExt[0]  = "jpeg"; $imgExtNum[0]  = 8;
  2037.             menuItem -label "Maya IFF (iff)";          //    $imgExt[1]  = "iff";  $imgExtNum[1]  = 7;
  2038.             menuItem -label "Maya16 IFF (iff)";        //    $imgExt[2]  = "iff";  $imgExtNum[2]  = 10;
  2039.             menuItem -label "MacPaint (pntg)";          //    $imgExt[3]  = "pntg"; $imgExtNum[3]  = 30;
  2040.             menuItem -label "Photoshop (ps)";        //    $imgExt[4]  = "ps";      $imgExtNum[4]  = 31;
  2041.             menuItem -label "PNG (png)";               //    $imgExt[5]  = "png";  $imgExtNum[5]  = 32;
  2042.             menuItem -label "QuickDraw (pict)";        //    $imgExt[6]  = "pict"; $imgExtNum[6]  = 33;
  2043.             menuItem -label "Quicktime Movie (qt)";    //    $imgExt[7]  = "qt";   $imgExtNum[7]  = 22;
  2044.             menuItem -label "Quicktime Image (qtif)";//    $imgExt[8]  = "qtif"; $imgExtNum[8]  = 34;
  2045.             menuItem -label "Silicon Graphics (sgi)";//    $imgExt[9] = "sgi";  $imgExtNum[9]  = 5;
  2046.             menuItem -label "Targa (tga)";            //    $imgExt[10] = "tga";  $imgExtNum[10] = 19;
  2047.             menuItem -label "Tiff (tif)";            //    $imgExt[11] = "tif";  $imgExtNum[11] = 3;
  2048.             menuItem -label "Windows Bitmap (bmp)";    //    $imgExt[12] = "bmp";  $imgExtNum[12] = 20;
  2049.         } else {
  2050.             warning "Unsupported platform in renderGlobalsWindow.mel";
  2051.         }
  2052.  
  2053.         }
  2054.  
  2055.         scriptJob -p $parent 
  2056.             -ac "defaultRenderGlobals.imageFormat" 
  2057.             "updateImageFile; updateFileOutputFeedback;";
  2058.  
  2059.         // Renderable Objects ------------------------------------------------
  2060.  
  2061.         //Note: not updating if changed elsewhere
  2062.         optionMenuGrp -label "Renderable Objects" -cc changeRenderObj renderObjMenu;
  2063.             menuItem -label "Render All";
  2064.             menuItem -label "Render Active";
  2065.  
  2066.         // Cameras ------------------------------------------------
  2067.  
  2068.         //Note: not updating if changed elsewhere
  2069.         optionMenuGrp -label "Camera" -cc switchCamera cameraMenu;
  2070.  
  2071.         // Channels ------------------------------------------------
  2072.  
  2073.         //Note: none of these are updating if changed elsewhere
  2074.         checkBoxGrp -numberOfCheckBoxes 1
  2075.                 -label "Channels"
  2076.                 -label1 "RGB Channel (Color)"
  2077.                 -cc updateCameraAttrs
  2078.                 rgbChannel;
  2079.  
  2080.         checkBoxGrp -numberOfCheckBoxes 1
  2081.                 -label1 "Alpha Channel (Mask)"
  2082.                 -cc updateCameraAttrs
  2083.                 alphaChannel;
  2084.  
  2085.         checkBoxGrp -numberOfCheckBoxes 1
  2086.                 -label1 "Depth Channel (Z Depth)"
  2087.                 -cc updateCameraAttrs
  2088.                 depthChannel;
  2089.  
  2090.     setParent ..;
  2091.     setUITemplate -popTemplate;
  2092. }
  2093.  
  2094. global proc createExtensionOptions (string $parent) 
  2095. //
  2096. //  Procedure Name:
  2097. //      createExtensionOptions
  2098. //
  2099. //  Description:
  2100. //      Creates the UI in the "Modify Extension" expand/collapse section.
  2101. //
  2102. {
  2103.     setUITemplate -pushTemplate attributeEditorTemplate;
  2104.  
  2105.     setParent $parent;
  2106.  
  2107.     // If the UI is created already then just update the attribute values.
  2108.     if (`columnLayout -exists rgExtOptionsLayout`) {
  2109.         updateExtOptions;
  2110.         return;
  2111.     }
  2112.  
  2113.     columnLayout -adjustableColumn true rgExtOptionsLayout;
  2114.  
  2115.         checkBoxGrp -numberOfCheckBoxes 1
  2116.             -label ""
  2117.             -label1 "Use Custom Extension:" 
  2118.             -cc changeCustomExtensionCheck
  2119.             imageCheckBox;
  2120.         scriptJob -p $parent 
  2121.             -ac "defaultRenderGlobals.outFormatControl" 
  2122.             "updateExtOptions; updateFileOutputFeedback;";
  2123.         
  2124.         textFieldGrp -label ""
  2125.             -text `getAttr "defaultRenderGlobals.outFormatExt"` 
  2126.             -cc changeCustomExtensionName 
  2127.             userExt;
  2128.         scriptJob -p $parent 
  2129.             -ac "defaultRenderGlobals.outFormatExt" 
  2130.             "updateExtOptions; updateFileOutputFeedback;";
  2131.  
  2132.     setParent ..;
  2133.  
  2134.     // Make sure the values are right
  2135.     updateExtOptions;
  2136.     setUITemplate -popTemplate;
  2137. }
  2138.  
  2139. global proc createFrameOptions (string $parent) 
  2140. //
  2141. //  Procedure Name:
  2142. //      createFrameOptions
  2143. //
  2144. //  Description:
  2145. //      Creates the UI in the "Renumber Frames" expand/collapse section.
  2146. //
  2147. {
  2148.     setUITemplate -pushTemplate attributeEditorTemplate;
  2149.  
  2150.     setParent $parent;
  2151.  
  2152.     // If the UI is created already then just update the attribute values.
  2153.     if (`columnLayout -exists rgFrameLayout`) {
  2154.         updateFrames;
  2155.         return;
  2156.     }
  2157.  
  2158.     columnLayout -adjustableColumn true rgFrameLayout;
  2159.  
  2160.         checkBoxGrp -numberOfCheckBoxes 1
  2161.             -label ""
  2162.             -label1 "Renumber Frames Using:"
  2163.             -cc "setAttr defaultRenderGlobals.modifyExtension #1; updateFrames; updateFileOutputFeedback"
  2164.             frameCheckBox;
  2165.         scriptJob -p $parent 
  2166.             -ac "defaultRenderGlobals.modifyExtension" 
  2167.             "updateFrames; updateFileOutputFeedback;";
  2168.         
  2169.         intFieldGrp -label "Start Number"
  2170.             -cc changeFrameExtension
  2171.             frameStartOverride;
  2172.         scriptJob -p $parent 
  2173.             -ac "defaultRenderGlobals.startExtension" 
  2174.             "updateFrames; updateFileOutputFeedback;";
  2175.  
  2176.         intFieldGrp -label "By Frame"
  2177.             -cc changeFrameExtension
  2178.             frameByOverride;
  2179.         scriptJob -p $parent 
  2180.             -ac "defaultRenderGlobals.byExtension" 
  2181.             "updateFrames; updateFileOutputFeedback;";
  2182.  
  2183.     setParent ..;
  2184.  
  2185.     // Make sure the values are right
  2186.     updateFrames;
  2187.     setUITemplate -popTemplate;
  2188. }
  2189.  
  2190. global proc createFieldOptions (string $parent) 
  2191. //
  2192. //  Procedure Name:
  2193. //      createFieldOptions
  2194. //
  2195. //  Description:
  2196. //      Creates the UI in the "Field Options" expand/collapse section.
  2197. //
  2198. {
  2199.     setUITemplate -pushTemplate attributeEditorTemplate;
  2200.  
  2201.     setParent $parent;
  2202.     string $cName;
  2203.  
  2204.     // If the UI is created already then just update the attribute values.
  2205.     if (`columnLayout -exists rgFieldLayout`) {
  2206.         updateFieldOptions;
  2207.         return;
  2208.     }
  2209.  
  2210.     columnLayout -adjustableColumn true rgFieldLayout;
  2211.  
  2212.         optionMenuGrp -label "Render" -cc changeFieldOptions fieldMenu;
  2213.             menuItem -label "Frames";
  2214.             menuItem -label "Both Fields, Interlaced";
  2215.             menuItem -label "Both Fields, Separate";
  2216.             menuItem -label "Odd Fields";
  2217.             menuItem -label "Even Fields";
  2218.         scriptJob -p $parent 
  2219.             -ac "defaultResolution.fields" 
  2220.             "updateFieldOptions; updateFileOutputFeedback;";
  2221.         
  2222.         optionMenuGrp -label "Field Dominance" 
  2223.             -cc "changeFieldOptions" fieldDominanceMenu;
  2224.         menuItem -label "Odd Field (NTSC)" rgOddField;
  2225.         menuItem -label "Even Field (PAL)" rgEvenField;
  2226.  
  2227.         radioButtonGrp -numberOfRadioButtons 2
  2228.             -label "Zeroth Scanline"
  2229.             -label1 "At Top" 
  2230.             -label2 "At Bottom" 
  2231.             -on1 "setAttr defaultResolution.zerothScanline 0"
  2232.             -on2 "setAttr defaultResolution.zerothScanline 1"
  2233.             scanlineButtons;
  2234.         scriptJob -p $parent 
  2235.             -ac "defaultResolution.zerothScanline" 
  2236.             "updateFieldOptions";
  2237.         
  2238.         separator;
  2239.  
  2240.         radioButtonGrp -numberOfRadioButtons 1
  2241.             -label ""
  2242.             -label1 "No Field Extension" 
  2243.             -onc changeFieldOptions
  2244.             fieldButton1;
  2245.  
  2246.         radioButtonGrp -numberOfRadioButtons 1  
  2247.             -shareCollection fieldButton1
  2248.             -label1 "Default Field Extension (o and e)" 
  2249.             -onc changeFieldOptions
  2250.             fieldButton2;
  2251.  
  2252.         radioButtonGrp -numberOfRadioButtons 1  
  2253.             -shareCollection fieldButton1
  2254.             -label1 "Custom Extension:" 
  2255.             -onc changeFieldOptions
  2256.             fieldButton3;
  2257.  
  2258.         // This works on the above 3 radio buttons
  2259.         scriptJob -p $parent 
  2260.             -ac "defaultRenderGlobals.fieldExtControl" 
  2261.             "updateFieldOptions; updateFileOutputFeedback;";
  2262.  
  2263.         // Make these fields small to indicate that
  2264.         // only a single character is accepted.
  2265.         // There's a SUG on this. #87405
  2266.         //
  2267.            textFieldGrp -label "Odd Field" 
  2268.             -cw 2 30 
  2269.             -cc changeFieldOptions oddFieldExt;
  2270.         scriptJob -p $parent 
  2271.             -ac "defaultRenderGlobals.oddFieldExt" 
  2272.             "updateFieldOptions; updateFileOutputFeedback;";
  2273.  
  2274.            textFieldGrp -label "Even Field" 
  2275.             -cw 2 30 
  2276.             -cc changeFieldOptions evenFieldExt;
  2277.         scriptJob -p $parent 
  2278.             -ac "defaultRenderGlobals.evenFieldExt" 
  2279.             "updateFieldOptions; updateFileOutputFeedback;";
  2280.  
  2281.     setParent ..;
  2282.     setUITemplate -popTemplate;
  2283.  
  2284.     // Make sure the values are right
  2285.     updateFieldOptions;
  2286. }
  2287.  
  2288. global proc createResolution (string $parent) 
  2289. //
  2290. //  Procedure Name:
  2291. //      createResolution
  2292. //
  2293. //  Description:
  2294. //      Creates the UI in the "Resolution" expand/collapse section.
  2295. //
  2296. {
  2297.     //
  2298.     // Make sure the list of predefined resolutions has been read in.
  2299.     //
  2300.     global string   $gImageFormatData[];
  2301.     global string   $gUserImageFormatData[];
  2302.  
  2303.     if (size($gImageFormatData) == 0) {
  2304.         eval("source imageFormats");
  2305.     }
  2306.  
  2307.     int $isMayaEvalVersion = `about -ev`;
  2308.     global string   $gPLEImageFormatData[];
  2309.     if ( $isMayaEvalVersion ) {
  2310.         $gImageFormatData = $gPLEImageFormatData;
  2311.     }
  2312.  
  2313.     if (exists("userImageFormats.mel") && size($gUserImageFormatData) == 0) {
  2314.         // Yes, we need the eval here, to avoid doing the source
  2315.         // until we know whether the file actually exists
  2316.         eval("source userImageFormats");
  2317.     }
  2318.  
  2319.     setUITemplate -pushTemplate attributeEditorTemplate;
  2320.  
  2321.     setParent $parent;
  2322.     string $cName;
  2323.  
  2324.     // If the UI is created already then just update the attribute values.
  2325.     if (`columnLayout -exists rgResolutionLayout`) {
  2326.         updateResolution;
  2327.         return;
  2328.     }
  2329.  
  2330.     global string   $gImageFormatData[];
  2331.     global string   $gUserImageFormatData[];
  2332.     columnLayout -adjustableColumn true rgResolutionLayout;
  2333.         int        $resItem;
  2334.         int        $numResolutionPresets = size($gImageFormatData);
  2335.         int        $numUserResolutionPresets = size($gUserImageFormatData);
  2336.         string  $allResNodes[] = `ls -type resolution`;
  2337.         int        $numResolutionNodePresets = size($allResNodes) - 1;
  2338.         int        $numTokens;
  2339.         string    $tokens[];
  2340.         string  $niceName;
  2341.  
  2342.         optionMenuGrp -label "Presets" 
  2343.             -cc "changeResolution" resolutionMenu;
  2344.         menuItem -label "Custom";
  2345.         for ($resItem = 0; $resItem < $numResolutionPresets; $resItem++) {
  2346.             string $item = $gImageFormatData[$resItem];
  2347.             $numTokens = tokenize($item, $tokens);
  2348.             //
  2349.             // Change any underscore into a space;
  2350.             // some names may have up to 2 underscores in them,
  2351.             // so we do this twice.
  2352.             $niceName = `substitute "_" $tokens[0] " "`;
  2353.             $niceName = `substitute "_" $niceName " "`;
  2354.             menuItem -label $niceName;
  2355.         }
  2356.         for ($resItem = 0; $resItem < $numUserResolutionPresets; $resItem++) {
  2357.             string $item = $gUserImageFormatData[$resItem];
  2358.             $numTokens = tokenize($item, $tokens);
  2359.             //
  2360.             // Change any underscore into a space;
  2361.             // some names may have up to 2 underscores in them,
  2362.             // so we do this twice.
  2363.             $niceName = `substitute "_" $tokens[0] " "`;
  2364.             $niceName = `substitute "_" $niceName " "`;
  2365.             menuItem -label $niceName;
  2366.         }
  2367.         for ($resItem = 0; $resItem < $numResolutionNodePresets; $resItem++) {
  2368.             menuItem -label $allResNodes[$resItem + 1];
  2369.         }
  2370.  
  2371.         separator;
  2372.         
  2373.         checkBoxGrp -numberOfCheckBoxes 1
  2374.             -label1 "Maintain Width/Height Ratio"
  2375.             -cc "setAttr defaultResolution.aspectLock #1;checkAspectLock \"defaultResolution\";updateResolution"
  2376.             aspectLockCheck;
  2377.  
  2378.         intFieldGrp -label "Width" 
  2379.             -cc "changeAspectLockWidth"
  2380.             resWidth;
  2381.         intFieldGrp -label "Height" 
  2382.             -cc changeAspectLockHeight
  2383.             resHeight;
  2384.         
  2385.         separator;
  2386.  
  2387.         checkBoxGrp -numberOfCheckBoxes 1
  2388.             -label1 "Lock Device Aspect Ratio" 
  2389.             -cc "setAttr defaultResolution.lockDeviceAspectRatio #1; changeAspectLockWidth"
  2390.             ratioLockCheck;
  2391.  
  2392.         floatFieldGrp -label "Device Aspect Ratio"  
  2393.             -cc "updateDeviceAspectRatio" resRatio;
  2394.  
  2395.         floatFieldGrp -label "Pixel Aspect Ratio"  
  2396.             -cc "rgAdjustDeviceAspect \"defaultResolution\"" pixRatio;
  2397.  
  2398.     setParent ..;
  2399.     setUITemplate -popTemplate;
  2400.  
  2401.     // Make sure the values are right
  2402.     updateResolution;
  2403. }
  2404.  
  2405. global proc createRayTraceQuality (string $parent) 
  2406. //
  2407. //  Procedure Name:
  2408. //      createRayTraceQuality
  2409. //
  2410. //  Description:
  2411. //      Creates the UI in the "Raytracing Quality" 
  2412. //        expand/collapse section.
  2413. //
  2414. {
  2415.     setUITemplate -pushTemplate attributeEditorTemplate;
  2416.  
  2417.     setParent $parent;
  2418.     string $cName;
  2419.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  2420.  
  2421.     // If the UI is created already then reset the command with the correct
  2422.     // render quality + update the attribute values.
  2423.     if (`columnLayout -exists rgRaytraceLayout`) {
  2424.         checkBoxGrp -e 
  2425.             -cc ("setAttr " + $rendQual[0] + ".enableRaytracing #1;updateRaytraceQuality")
  2426.             raytraceCheck;
  2427.         intSliderGrp -e 
  2428.             -cc ("setAttr " + $rendQual[0] + ".reflections #1")
  2429.             reflectionsField;
  2430.         intSliderGrp -e
  2431.             -cc ("setAttr " + $rendQual[0] + ".refractions #1")
  2432.             refractionsField;
  2433.         intSliderGrp -e
  2434.             -cc ("setAttr " + $rendQual[0] + ".shadows #1")
  2435.             shadowsField;
  2436.         floatSliderGrp -e
  2437.             -cc ("setAttr " + $rendQual[0] + ".rayTraceBias #1")
  2438.             rayTraceBiasField;
  2439.  
  2440.         updateRaytraceQuality;
  2441.         return;
  2442.     }
  2443.  
  2444.     columnLayout -adjustableColumn true rgRaytraceLayout;
  2445.         
  2446.         checkBoxGrp -numberOfCheckBoxes 1
  2447.             -label1 "Raytracing"
  2448.             -cc ("setAttr " + $rendQual[0] + ".enableRaytracing #1;updateRaytraceQuality")
  2449.             raytraceCheck;
  2450.  
  2451.         intSliderGrp -label "Reflections"
  2452.             -cc ("setAttr " + $rendQual[0] + ".reflections #1")
  2453.             -min 0 -max 20 reflectionsField;
  2454.  
  2455.         intSliderGrp -label "Refractions"
  2456.             -cc ("setAttr " + $rendQual[0] + ".refractions #1")
  2457.             -min 0 -max 20 refractionsField;
  2458.  
  2459.         intSliderGrp -label "Shadows"
  2460.             -cc ("setAttr " + $rendQual[0] + ".shadows #1")
  2461.             -min 0 -max 20 shadowsField;
  2462.  
  2463.         floatSliderGrp -label "Bias"
  2464.             -cc ("setAttr " + $rendQual[0] + ".rayTraceBias #1")
  2465.             -min 0.0 -max 1.0 rayTraceBiasField;
  2466.  
  2467.     setParent ..;
  2468.     setUITemplate -popTemplate;
  2469.  
  2470.     // Make sure the values are right
  2471.     updateRaytraceQuality;
  2472. }
  2473.  
  2474. global proc createRenderQuality (string $parent) 
  2475. //
  2476. //  Procedure Name:
  2477. //      createRenderQuality
  2478. //
  2479. //  Description:
  2480. //      Creates the UI in the "Anti-aliasing Quality" 
  2481. //        expand/collapse section.
  2482. //
  2483. {
  2484.     setUITemplate -pushTemplate attributeEditorTemplate;
  2485.  
  2486.     setParent $parent;
  2487.     string $cName;
  2488.  
  2489.     // If the UI is created already then reset the command with the correct
  2490.     // render quality + update the attribute values.
  2491.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  2492.     if (`columnLayout -exists rgQualityLayout`) {
  2493.         intSliderGrp -e
  2494.             -cc ("setAttr " + $rendQual[0] + ".shadingSamples #1;updateRenderQuality")
  2495.             shadingSamplesField;
  2496.         intSliderGrp -e 
  2497.             -cc ("setAttr " + $rendQual[0] + ".maxShadingSamples #1;updateRenderQuality")
  2498.             maxShadingSamplesField;
  2499.         intSliderGrp -e
  2500.             -cc ("setAttr " + $rendQual[0] + ".visibilitySamples #1;updateRenderQuality")
  2501.             visSamplesField;
  2502.         intSliderGrp -e
  2503.             -cc ("setAttr " + $rendQual[0] + ".maxVisibilitySamples #1;updateRenderQuality")
  2504.             maxVisSamplesField;
  2505.         intSliderGrp -e
  2506.             -cc ("setAttr " + $rendQual[0] + ".particleSamples #1;updateRenderQuality")
  2507.             particlesSamplesField;
  2508.         checkBoxGrp -e
  2509.             -cc ("setAttr " + $rendQual[0] + ".useMultiPixelFilter #1;updateRenderQuality")
  2510.             pixelCheck;
  2511.         floatSliderGrp -e
  2512.             -cc ("setAttr " + $rendQual[0] + ".pixelFilterWidthX #1")
  2513.             filterXField;
  2514.         floatSliderGrp -e
  2515.             -cc ("setAttr " + $rendQual[0] + ".pixelFilterWidthY #1")
  2516.             filterYField;
  2517.         floatSliderGrp -e
  2518.             -cc ("setAttr " + $rendQual[0] + ".redThreshold #1; updateRenderQuality")
  2519.             contrastRedField;
  2520.         floatSliderGrp -e
  2521.             -cc ("setAttr " + $rendQual[0] + ".greenThreshold #1; updateRenderQuality")
  2522.             contrastGreenField;
  2523.         floatSliderGrp -e
  2524.             -cc ("setAttr " + $rendQual[0] + ".blueThreshold #1; updateRenderQuality")
  2525.             contrastBlueField;
  2526.         floatSliderGrp -e
  2527.             -cc ("setAttr " + $rendQual[0] + ".coverageThreshold #1")
  2528.             contrastCoverField;
  2529.  
  2530.         updateRenderQuality;
  2531.         return;
  2532.     }
  2533.  
  2534.     columnLayout -adjustableColumn true rgQualityLayout;
  2535.  
  2536.         frameLayout 
  2537.             -labelVisible false -borderVisible true 
  2538.             -borderStyle "etchedIn"
  2539.             -collapsable false -collapse true;
  2540.         columnLayout -adjustableColumn true;
  2541.         
  2542.         optionMenuGrp -label "Presets" qualityPresetMenu;
  2543.         optionMenuGrp -edit -cc RGsetDefaultQuality -cw 2 240 qualityPresetMenu;
  2544.             
  2545.             menuItem -label "Custom" rgCustomQuality;
  2546.             menuItem -label "Preview Quality" rgPreviewQuality;
  2547.             menuItem -label "Intermediate Quality" rgIntermediateQuality;
  2548.             menuItem -label "Production Quality" rgProductionQuality;
  2549.             menuItem -label "Contrast Sensitive Production" rgContrastProductionQuality;
  2550.             menuItem -label "3D Motion Blur Production" rgMotionBlurQuality;
  2551.         
  2552.         optionMenuGrp -label "Edge Anti-aliasing" 
  2553.             -cc RGsetEdgeQuality edgeMenu;
  2554.             
  2555.             menuItem -label "Low Quality";
  2556.             menuItem -label "Medium Quality";
  2557.             menuItem -label "High Quality";
  2558.             menuItem -label "Highest Quality";
  2559.                         
  2560.         setParent ..;
  2561.         setParent ..;
  2562.  
  2563.         frameLayout -label "Number of Samples" 
  2564.             -labelVisible true -borderVisible true 
  2565.             -borderStyle "etchedIn"
  2566.             -labelAlign "center" -labelWidth 150
  2567.             -collapsable false -collapse true;
  2568.         columnLayout -adjustableColumn true;
  2569.         
  2570.             intSliderGrp -label "Shading"
  2571.                 -cc ("setAttr " + $rendQual[0] + ".shadingSamples #1;updateRenderQuality")
  2572.                 -min 1 -max 20 shadingSamplesField;
  2573.        
  2574.             intSliderGrp -label "Max Shading"
  2575.                 -cc ("setAttr " + $rendQual[0] + ".maxShadingSamples #1;updateRenderQuality")
  2576.                 -min 1 -max 20 maxShadingSamplesField;
  2577.         
  2578.             intSliderGrp -label "3D Blur Visib."
  2579.                 -cc ("setAttr " + $rendQual[0] + ".visibilitySamples #1;updateRenderQuality")
  2580.                 -min 1 -max 20 visSamplesField;
  2581.         
  2582.             intSliderGrp -label "Max 3D Blur Visib."
  2583.                 -cc ("setAttr " + $rendQual[0] + ".maxVisibilitySamples #1;updateRenderQuality")
  2584.                 -min 1 -max 20 maxVisSamplesField;
  2585.         
  2586.             intSliderGrp -label "Particles"
  2587.                 -cc ("setAttr " + $rendQual[0] + ".particleSamples #1;updateRenderQuality")
  2588.                 -min 1 -max 20 particlesSamplesField;
  2589.                         
  2590.         setParent ..;
  2591.         setParent ..;
  2592.  
  2593.         frameLayout -label "Multipixel Filtering" 
  2594.             -labelVisible true -borderVisible true 
  2595.             -borderStyle "etchedIn"
  2596.             -labelAlign "center" -labelWidth 150
  2597.             -collapsable false -collapse true;
  2598.         columnLayout -adjustableColumn true;
  2599.  
  2600.             checkBoxGrp -numberOfCheckBoxes 1
  2601.                 -label1 "Use Multi Pixel Filter"
  2602.                 -cc ("setAttr " + $rendQual[0] + ".useMultiPixelFilter #1;updateRenderQuality")
  2603.                 pixelCheck;
  2604.  
  2605.             optionMenuGrp -label "Pixel Filter Type" 
  2606.                 -cc "RGsetPixelFilterType" pixelFilterMenu;
  2607.             
  2608.                 menuItem -label "Box Filter";
  2609.                 menuItem -label "Triangle Filter";
  2610.                 menuItem -label "Gaussian Filter";
  2611.                 menuItem -label "Quadratic B-Spline Filter";
  2612.                 menuItem -label "Plug-in Filter";
  2613.         
  2614.             floatSliderGrp -label "Pixel Filter Width X"
  2615.                 -cc ("setAttr " + $rendQual[0] + ".pixelFilterWidthX #1")
  2616.                 -min 1.0 -max 3.0 filterXField;
  2617.         
  2618.             floatSliderGrp -label "Pixel Filter Width Y"
  2619.                 -cc ("setAttr " + $rendQual[0] + ".pixelFilterWidthY #1")
  2620.                 -min 1.0 -max 3.0 filterYField;
  2621.        
  2622.         setParent ..;
  2623.         setParent ..;
  2624.         
  2625.  
  2626.         frameLayout -label "Contrast Threshold" 
  2627.             -labelVisible true -borderVisible true 
  2628.             -borderStyle "etchedIn"
  2629.             -labelAlign "center" -labelWidth 150
  2630.             -collapsable false -collapse true;
  2631.         columnLayout -adjustableColumn true;
  2632.         
  2633.             floatSliderGrp -label "Red"
  2634.                 -cc ("setAttr " + $rendQual[0] + ".redThreshold #1; updateRenderQuality")
  2635.                 -min 0.0 -max 1.0 contrastRedField;
  2636.         
  2637.             floatSliderGrp -label "Green"
  2638.                 -cc ("setAttr " + $rendQual[0] + ".greenThreshold #1; updateRenderQuality")
  2639.                 -min 0.0 -max 1.0 contrastGreenField;
  2640.         
  2641.             floatSliderGrp -label "Blue"
  2642.                 -cc ("setAttr " + $rendQual[0] + ".blueThreshold #1; updateRenderQuality")
  2643.                 -min 0.0 -max 1.0 contrastBlueField;
  2644.         
  2645.             floatSliderGrp -label "Coverage"
  2646.                 -cc ("setAttr " + $rendQual[0] + ".coverageThreshold #1")
  2647.                 -min 0.0 -max 1.0 contrastCoverField;
  2648.                         
  2649.         setParent ..;
  2650.         setParent ..;
  2651.  
  2652.     setParent ..;
  2653.     setUITemplate -popTemplate;
  2654.  
  2655.     // Make sure the values are right
  2656.     updateRenderQuality;
  2657. }
  2658.  
  2659. global proc RGsetPixelFilterType()
  2660. {
  2661.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  2662.     string $curr = `optionMenuGrp -q -v pixelFilterMenu`;
  2663.     if ($curr == "Box Filter") {
  2664.         setAttr ($rendQual[0] + ".pixelFilterType") 0;
  2665.     } else if ($curr == "Triangle Filter") {
  2666.         setAttr ($rendQual[0] + ".pixelFilterType") 2;
  2667.     } else if ($curr == "Gaussian Filter") {
  2668.         setAttr ($rendQual[0] + ".pixelFilterType") 4;
  2669.     } else if ($curr == "Quadratic B-Spline Filter") {
  2670.         setAttr ($rendQual[0] + ".pixelFilterType") 5;
  2671.     } else if ($curr == "Plug-in Filter") {
  2672.         setAttr ($rendQual[0] + ".pixelFilterType") 1000;
  2673.     }
  2674.     updateRenderQuality;
  2675. }
  2676.  
  2677. global proc RGsetDefaultQuality ()
  2678. {
  2679.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  2680.     string $curr = `optionMenuGrp -q -v qualityPresetMenu`;
  2681.     if ($curr == "Preview Quality") {
  2682.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 3;
  2683.         setAttr ($rendQual[0] + ".useMultiPixelFilter") 0;
  2684.         setAttr ($rendQual[0] + ".shadingSamples") 1;
  2685.         setAttr ($rendQual[0] + ".maxShadingSamples") 1;
  2686.         setAttr ($rendQual[0] + ".visibilitySamples") 1;
  2687.         setAttr ($rendQual[0] + ".maxVisibilitySamples") 4;
  2688.         setAttr ($rendQual[0] + ".redThreshold") 0.4;
  2689.         setAttr ($rendQual[0] + ".greenThreshold") 0.3;
  2690.         setAttr ($rendQual[0] + ".blueThreshold") 0.6;
  2691.         setAttr ($rendQual[0] + ".reflections") 1;
  2692.         setAttr ($rendQual[0] + ".refractions") 6;
  2693.         setAttr ($rendQual[0] + ".shadows") 2;
  2694.     } else if ($curr == "Intermediate Quality") {
  2695.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 0;
  2696.         setAttr ($rendQual[0] + ".useMultiPixelFilter") 0;
  2697.         setAttr ($rendQual[0] + ".shadingSamples") 1;
  2698.         setAttr ($rendQual[0] + ".maxShadingSamples") 8;
  2699.         setAttr ($rendQual[0] + ".visibilitySamples") 1;
  2700.         setAttr ($rendQual[0] + ".maxVisibilitySamples") 4;
  2701.         setAttr ($rendQual[0] + ".redThreshold") 0.4;
  2702.         setAttr ($rendQual[0] + ".greenThreshold") 0.3;
  2703.         setAttr ($rendQual[0] + ".blueThreshold") 0.6;
  2704.         setAttr ($rendQual[0] + ".reflections") 1;
  2705.         setAttr ($rendQual[0] + ".refractions") 6;
  2706.         setAttr ($rendQual[0] + ".shadows") 2;
  2707.     } else if ($curr == "Production Quality") {
  2708.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 0;
  2709.         setAttr ($rendQual[0] + ".useMultiPixelFilter") 1;
  2710.         setAttr ($rendQual[0] + ".shadingSamples") 2;
  2711.         setAttr ($rendQual[0] + ".maxShadingSamples") 8;
  2712.         setAttr ($rendQual[0] + ".visibilitySamples") 1;
  2713.         setAttr ($rendQual[0] + ".maxVisibilitySamples") 4;
  2714.         setAttr ($rendQual[0] + ".redThreshold") 0.4;
  2715.         setAttr ($rendQual[0] + ".greenThreshold") 0.3;
  2716.         setAttr ($rendQual[0] + ".blueThreshold") 0.6;
  2717.         setAttr ($rendQual[0] + ".reflections") 10;
  2718.         setAttr ($rendQual[0] + ".refractions") 10;
  2719.         setAttr ($rendQual[0] + ".shadows") 10;
  2720.     } else if ($curr == "Contrast Sensitive Production") {
  2721.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 0;
  2722.         setAttr ($rendQual[0] + ".useMultiPixelFilter") 1;
  2723.         setAttr ($rendQual[0] + ".shadingSamples") 2;
  2724.         setAttr ($rendQual[0] + ".maxShadingSamples") 8;
  2725.         setAttr ($rendQual[0] + ".visibilitySamples") 1;
  2726.         setAttr ($rendQual[0] + ".maxVisibilitySamples") 4;
  2727.         setAttr ($rendQual[0] + ".redThreshold") 0.2;
  2728.         setAttr ($rendQual[0] + ".greenThreshold") 0.15;
  2729.         setAttr ($rendQual[0] + ".blueThreshold") 0.3;
  2730.         setAttr ($rendQual[0] + ".reflections") 10;
  2731.         setAttr ($rendQual[0] + ".refractions") 10;
  2732.         setAttr ($rendQual[0] + ".shadows") 10;
  2733.     } else if ($curr == "3D Motion Blur Production") {
  2734.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 0;
  2735.         setAttr ($rendQual[0] + ".useMultiPixelFilter") 1;
  2736.         setAttr ($rendQual[0] + ".shadingSamples") 3;
  2737.         setAttr ($rendQual[0] + ".maxShadingSamples") 8;
  2738.         setAttr ($rendQual[0] + ".visibilitySamples") 1;
  2739.         setAttr ($rendQual[0] + ".maxVisibilitySamples") 4;
  2740.         setAttr ($rendQual[0] + ".redThreshold") 0.4;
  2741.         setAttr ($rendQual[0] + ".greenThreshold") 0.3;
  2742.         setAttr ($rendQual[0] + ".blueThreshold") 0.6;
  2743.         setAttr ($rendQual[0] + ".reflections") 10;
  2744.         setAttr ($rendQual[0] + ".refractions") 10;
  2745.         setAttr ($rendQual[0] + ".shadows") 10;
  2746.     }
  2747.     updateRenderQuality;
  2748.  
  2749.     if (`columnLayout -exists rgRaytraceLayout`) updateRaytraceQuality;
  2750. }
  2751.  
  2752. global proc RGsetEdgeQuality()
  2753. {
  2754.     string $rendQual[] = `listConnections defaultRenderGlobals.qual`;
  2755.     string $curr = `optionMenuGrp -q -v edgeMenu`;
  2756.     if ($curr == "Low Quality") {
  2757.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 3;
  2758.     } else if ($curr == "Medium Quality") {
  2759.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 2;
  2760.     } else if ($curr == "High Quality") {
  2761.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 1;
  2762.     } else {
  2763.         setAttr ($rendQual[0] + ".edgeAntiAliasing") 0;
  2764.     }
  2765.  
  2766.     updateRenderQuality;
  2767. }
  2768.  
  2769. global proc createRenderOptions (string $parent) 
  2770. //
  2771. //  Procedure Name:
  2772. //      createRenderOptions
  2773. //
  2774. //  Description:
  2775. //      Creates the UI in the "Render Options" expand/collapse section.
  2776. //
  2777. {
  2778.     setUITemplate -pushTemplate attributeEditorTemplate;
  2779.  
  2780.     setParent $parent;
  2781.     string $cName;
  2782.  
  2783.     // If the UI is created already then just update the attribute values.
  2784.     if (`columnLayout -exists rgOptionsLayout`) {
  2785.         updateRenderOptions;
  2786.         return;
  2787.     }
  2788.  
  2789.     columnLayout -adjustableColumn true rgOptionsLayout;
  2790.  
  2791.            textFieldGrp -label "Plug-in Format" 
  2792.             -cc "setAttr defaultRenderGlobals.pluginFormat -type \"string\" \"#1\""
  2793.             plugInFormat;
  2794.         
  2795.            textFieldGrp -label "Pre Render MEL" 
  2796.             -cc "setAttr defaultRenderGlobals.preRenderMel -type \"string\" \"#1\""
  2797.             preRenderMel;
  2798.         
  2799.            textFieldGrp -label "Post Render MEL" 
  2800.             -cc "setAttr defaultRenderGlobals.postRenderMel -type \"string\" \"#1\""
  2801.             postRenderMel;
  2802.     
  2803.         separator;
  2804.         attrNavigationControlGrp -l "Environment Fog"
  2805.                 -at defaultRenderGlobals.fogGeometry envFogControl;
  2806.         if (`isTrue MayaCreatorExists`) {
  2807.             checkBoxGrp -numberOfCheckBoxes 1
  2808.                 -label1 "Apply Fog in Post" 
  2809.                 -cc "setAttr defaultRenderGlobals.applyFogInPost #1;intFieldGrp -edit -enable #1 postFogBlurField;"
  2810.                 applyFogInPostCheck;
  2811.             intFieldGrp -label "Post Fog Blur"
  2812.                 -cc "setAttr defaultRenderGlobals.postFogBlur #1"
  2813.                 -enable `getAttr defaultRenderGlobals.applyFogInPost`
  2814.                 postFogBlurField;
  2815.             separator;
  2816.         }
  2817.  
  2818.         checkBoxGrp -numberOfCheckBoxes 1
  2819.             -label1 "Shadows Obey Light Linking" 
  2820.             -cc "setAttr defaultRenderGlobals.shadowsObeyLightLinking #1;"
  2821.             shadowLightLinkCheck;
  2822.         
  2823.         checkBoxGrp -numberOfCheckBoxes 1
  2824.             -label1 "Enable Depth Maps"
  2825.             -cc "setAttr defaultRenderGlobals.enableDepthMaps #1"
  2826.             depthMapCheck;
  2827.  
  2828.         checkBoxGrp -numberOfCheckBoxes 1
  2829.             -label1 "Enable Default Light"
  2830.             -cc "setAttr defaultRenderGlobals.enableDefaultLight #1"
  2831.             defaultLightCheck;
  2832.  
  2833.         checkBoxGrp -numberOfCheckBoxes 1
  2834.             -label1 "Ignore Film Gate"
  2835.             -cc "setAttr defaultRenderGlobals.ignoreFilmGate #1"
  2836.             filmGateCheck;
  2837.  
  2838.         checkBoxGrp -numberOfCheckBoxes 1
  2839.             -label1 "Clip Final Shaded Color"
  2840.             -cc "setAttr defaultRenderGlobals.clipFinalShadedColor #1"
  2841.             clipCheck;
  2842.  
  2843.         checkBoxGrp -numberOfCheckBoxes 1
  2844.             -label1 "Jitter Final Color"
  2845.             -cc "setAttr defaultRenderGlobals.jitterFinalColor #1"
  2846.             jitterColor;
  2847.         
  2848.         floatFieldGrp -label "Gamma Correction"
  2849.             -cc "setAttr defaultRenderGlobals.gammaCorrection #1"
  2850.             gammaField;
  2851.     
  2852.         separator;
  2853.         
  2854.         checkBoxGrp -numberOfCheckBoxes 1
  2855.             -label1 "Composite" 
  2856.             -cc "setAttr defaultRenderGlobals.composite #1;floatFieldGrp -edit -enable #1 compValueField;"
  2857.             compCheck;
  2858.         
  2859.         floatFieldGrp -label "Composite Threshold"
  2860.             -cc "setAttr defaultRenderGlobals.compositeThreshold #1"
  2861.             compValueField;
  2862.  
  2863.     setParent ..;
  2864.     setUITemplate -popTemplate;
  2865.  
  2866.     // Make sure the values are right
  2867.     updateRenderOptions;
  2868. }
  2869.  
  2870.  
  2871. global proc updateNumCpusSlider(int $value)
  2872. //
  2873. //  Procedure Name:
  2874. //      updateNumCpusSlider
  2875. //
  2876. //  Description:
  2877. //      When the controls for the number of CPUs are updated this
  2878. //      procedure will be invoked. The check box, field and slider
  2879. //      will be update to reflect the new value. If the value is
  2880. //      zero, all CPUs will be used.
  2881. //
  2882. {
  2883.     if ( `about -evalVersion` ) {
  2884.         warning( "Maya Personal Learning Edition limits rendering to a single CPU");
  2885.         checkBoxGrp -e -enable false -value1 false numCpusCheckBox;
  2886.         intSliderGrp -e -enable false -value 1 numCpusSlider;
  2887.         return;
  2888.     }
  2889.  
  2890.     if ($value == 0) {
  2891.         checkBoxGrp -e -value1 true numCpusCheckBox;
  2892.  
  2893.         intSliderGrp -e -enable false -value $value numCpusSlider;
  2894.     }
  2895.     else {
  2896.         checkBoxGrp -e -value1 false numCpusCheckBox;
  2897.  
  2898.         intSliderGrp -e -enable true -value $value numCpusSlider;
  2899.  
  2900.         if (`iprEngine -query -exists defaultIprEngine`) {
  2901.             warning -showLineNumber false
  2902.                 ("IPR will need to be closed before this change in CPUs will"+
  2903.                 " take effect.");
  2904.         }
  2905.     }
  2906.  
  2907.     setAttr defaultRenderGlobals.numCpusToUse $value;
  2908. }
  2909.  
  2910. global proc updatePerformanceOptions ()
  2911. //
  2912. //  Procedure Name:
  2913. //      updatePerformanceOptions
  2914. //
  2915. //  Description:
  2916. //      Gets the real values from the nodes and sets the UI based
  2917. //        on these values.  This procedure updates all of the memory
  2918. //        and performance values.
  2919. //
  2920. { 
  2921.     checkBoxGrp -edit
  2922.         -v1 `getAttr defaultRenderGlobals.useFileCache`
  2923.         cacheCheck;
  2924.     
  2925.     checkBoxGrp -edit
  2926.         -v1 `getAttr defaultRenderGlobals.optimizeInstances`
  2927.         optCheck;
  2928.     
  2929.     checkBoxGrp -edit
  2930.         -v1 `getAttr defaultRenderGlobals.reuseTessellations`
  2931.         reuseCheck;
  2932.  
  2933.     checkBoxGrp -edit
  2934.         -v1 `getAttr defaultRenderGlobals.useDisplacementBoundingBox`
  2935.         dispBBCheck;
  2936.  
  2937.     intSliderGrp -edit
  2938.         -v `getAttr defaultRenderGlobals.recursionDepth`
  2939.         recursionDepth;
  2940.  
  2941.     intSliderGrp -edit
  2942.         -v `getAttr defaultRenderGlobals.leafPrimitives`
  2943.         leafPrim;
  2944.  
  2945.     floatSliderGrp -edit
  2946.         -v `getAttr defaultRenderGlobals.subdivisionPower`
  2947.         subPower;
  2948.  
  2949. //    intSliderGrp -edit
  2950. //        -v `getAttr defaultRenderGlobals.subdivisionHashSize`
  2951. //        subHash;
  2952.  
  2953.     updateNumCpusSlider(`getAttr defaultRenderGlobals.numCpusToUse`);
  2954. }
  2955.  
  2956.  
  2957. global proc createPerformanceOptions (string $parent) 
  2958. //
  2959. //  Procedure Name:
  2960. //      createPerformanceOptions
  2961. //
  2962. //  Description:
  2963. //      Creates the UI in the "Memory and Performance Options" 
  2964. //        expand/collapse section.
  2965. //
  2966. {
  2967.     setUITemplate -pushTemplate attributeEditorTemplate;
  2968.  
  2969.     setParent $parent;
  2970.     string $cName;
  2971.  
  2972.     // If the UI is created already then just update the attribute values.
  2973.     if (`columnLayout -exists rgPerformanceLayout`) {
  2974.         updatePerformanceOptions;
  2975.         return;
  2976.     }
  2977.  
  2978.     columnLayout -adjustableColumn true rgPerformanceLayout;
  2979.  
  2980.         frameLayout -label "Tessellation" 
  2981.             -labelVisible true -borderVisible true 
  2982.             -borderStyle "etchedIn"
  2983.             -labelAlign "center" -labelWidth 100
  2984.             -collapsable false -collapse true;
  2985.         columnLayout -adjustableColumn true;
  2986.     
  2987.             checkBoxGrp -numberOfCheckBoxes 1
  2988.                 -label1 "Use File Cache" 
  2989.                 -cc "setAttr defaultRenderGlobals.useFileCache #1;"
  2990.                 cacheCheck;
  2991.         
  2992.             checkBoxGrp -numberOfCheckBoxes 1
  2993.                 -label1 "Optimize Instances" 
  2994.                 -cc "setAttr defaultRenderGlobals.optimizeInstances #1;"
  2995.                 optCheck;
  2996.     
  2997.             checkBoxGrp -numberOfCheckBoxes 1
  2998.                 -label1 "Reuse Tessellations" 
  2999.                 -cc "setAttr defaultRenderGlobals.reuseTessellations #1;"
  3000.                 reuseCheck;
  3001.  
  3002.             checkBoxGrp -numberOfCheckBoxes 1
  3003.                 -label1 "Use Displacement Bounding Box" 
  3004.                 -cc "setAttr defaultRenderGlobals.useDisplacementBoundingBox #1;"
  3005.                 dispBBCheck;
  3006.  
  3007.         setParent ..;
  3008.         setParent ..;
  3009.  
  3010.         frameLayout -label "Ray Tracing" 
  3011.             -labelVisible true -borderVisible true 
  3012.             -borderStyle "etchedIn"
  3013.             -labelAlign "center"  -labelWidth 100
  3014.             -collapsable false -collapse true;
  3015.         columnLayout -adjustableColumn true;
  3016.     
  3017.             intSliderGrp -label "Recursion Depth"
  3018.                 -min 1 -max 5
  3019.                 -cc "setAttr defaultRenderGlobals.recursionDepth `intSliderGrp -q -v recursionDepth`"
  3020.                 recursionDepth;
  3021.  
  3022.             intSliderGrp -label "Leaf Primitives"
  3023.                 -min 20 -max 200
  3024.                 -cc "setAttr defaultRenderGlobals.leafPrimitives `intSliderGrp -q -v leafPrim`"
  3025.                 leafPrim;
  3026.  
  3027.             floatSliderGrp -label "Subdivision Power"
  3028.                 -min 0.01 -max 1.0
  3029.                 -cc "setAttr defaultRenderGlobals.subdivisionPower `floatSliderGrp -q -v subPower`"
  3030.                 subPower;
  3031.  
  3032. //            intSliderGrp -label "Subdiv Hash Size"
  3033. //                -min 1 -max 100
  3034. //                -cc "setAttr defaultRenderGlobals.subdivisionHashSize `intSliderGrp -q -v subHash`"
  3035. //                subHash;
  3036.  
  3037.         setParent ..;
  3038.         setParent ..;
  3039.  
  3040.         frameLayout -label "Multi Processing" 
  3041.             -labelVisible true -borderVisible true 
  3042.             -borderStyle "etchedIn"
  3043.             -labelAlign "center"  -labelWidth 100
  3044.             -collapsable false -collapse true;
  3045.         columnLayout -adjustableColumn true;
  3046.         
  3047.             checkBoxGrp -numberOfCheckBoxes 1
  3048.                 -label1 "Use All Available CPUs"
  3049.                 -cc "updateNumCpusSlider(#1 ? 0 : 1)"
  3050.                 numCpusCheckBox;
  3051.  
  3052.             intSliderGrp
  3053.                 -label "Num. CPUs to Use"
  3054.                 -cc "updateNumCpusSlider(#1)"
  3055.                 -minValue 1 -maxValue 8
  3056.                 -fieldMinValue 0 -fieldMaxValue 256
  3057.                 numCpusSlider;
  3058.  
  3059.         setParent ..;
  3060.         setParent ..;
  3061.  
  3062.     setParent ..;
  3063.     setUITemplate -popTemplate;
  3064.  
  3065.     // Make sure the values are right
  3066.     updatePerformanceOptions;
  3067. }
  3068.  
  3069.  
  3070. global proc updateIPROptions ()
  3071. //
  3072. //  Procedure Name:
  3073. //      updateIPROptions
  3074. //
  3075. //  Description:
  3076. //      Gets the real values from the option vars and sets the UI based
  3077. //        on these values.  This procedure updates all of the IPR
  3078. //        values.
  3079. //
  3080. { 
  3081.     int $doShading = `optionVar -query iprRenderShading`;
  3082.     checkBoxGrp -edit -v1 $doShading iprShadingCheck;
  3083.     checkBoxGrp -edit -v1 `optionVar -query iprRenderShadowMaps` 
  3084.         -enable $doShading iprShadowCheck;
  3085.     checkBoxGrp -edit -v1 `optionVar -query iprRenderMotionBlur` ipr2DBlurCheck;
  3086. }
  3087.  
  3088. global proc updateIPRShadingOptionVar()
  3089. {
  3090.     int $doShading = `checkBoxGrp -q -v1 iprShadingCheck`;
  3091.     optionVar -intValue iprRenderShading $doShading;
  3092.     checkBoxGrp -edit -enable $doShading iprShadowCheck;
  3093. }
  3094.  
  3095. global proc updateIPRShadowOptionVar()
  3096. {
  3097.     int $doShadows = `checkBoxGrp -q -v1 iprShadowCheck`;
  3098.     optionVar -intValue iprRenderShadowMaps $doShadows;
  3099. }
  3100.  
  3101. global proc updateIPR2dBlurOptionVar()
  3102. {
  3103.     int $doBlur = `checkBoxGrp -q -v1 ipr2DBlurCheck`;
  3104.     optionVar -intValue iprRenderMotionBlur $doBlur;
  3105. }
  3106.  
  3107. global proc createIPROptions (string $parent) 
  3108. //
  3109. //  Procedure Name:
  3110. //      createIPROptions
  3111. //
  3112. //  Description:
  3113. //      Creates the UI in the "IPR Render Globals" 
  3114. //        expand/collapse section.
  3115. //
  3116. {
  3117.     setUITemplate -pushTemplate attributeEditorTemplate;
  3118.  
  3119.     setParent $parent;
  3120.     string $cName;
  3121.  
  3122.     // If the UI is created already then just update the attribute values.
  3123.     if (`columnLayout -exists rgIPRLayout`) {
  3124.         updateIPROptions;
  3125.         return;
  3126.     }
  3127.  
  3128.     columnLayout -adjustableColumn true rgIPRLayout;
  3129.         checkBoxGrp -numberOfCheckBoxes 1
  3130.             -label1 "Render Shading, Lighting and Glow" 
  3131.             -cc "updateIPRShadingOptionVar"
  3132.             iprShadingCheck;
  3133.  
  3134.         checkBoxGrp -numberOfCheckBoxes 1
  3135.             -label1 "Render Shadow Maps" 
  3136.             -cc "updateIPRShadowOptionVar"
  3137.             iprShadowCheck;
  3138.  
  3139.         checkBoxGrp -numberOfCheckBoxes 1
  3140.             -label1 "Render 2D Motion Blur" 
  3141.             -cc "updateIPR2dBlurOptionVar"
  3142.             ipr2DBlurCheck;
  3143.  
  3144.     setParent ..;
  3145.     setUITemplate -popTemplate;
  3146.  
  3147.     // Make sure the values are right
  3148.     updateIPROptions;
  3149. }
  3150.  
  3151. global proc updateUrchinOptions ()
  3152. //
  3153. //  Procedure Name:
  3154. //      updateUrchinOptions
  3155. //
  3156. //  Description:
  3157. //      Gets the real values from the nodes and sets the UI based
  3158. //        on these values.  This procedure updates all of the memory
  3159. //        and performance values. I guess hard-coding the render globals
  3160. //      name is okay until we handle multiple nodes, and since every
  3161. //      other routine in this file makes that assumption, so will I.
  3162. //
  3163. { 
  3164.     checkBoxGrp -edit
  3165.         -v1 `getAttr defaultRenderGlobals.enableStrokeRender`
  3166.         enableStrokesCheck;
  3167.     
  3168.     checkBoxGrp -edit
  3169.         -v1 `getAttr defaultRenderGlobals.onlyRenderStrokes`
  3170.         onlyStrokesCheck;
  3171.     
  3172.     checkBoxGrp -edit
  3173.         -v1 `getAttr defaultRenderGlobals.oversamplePaintEffects`
  3174.         oversamplePaintEffectsCheck;
  3175.  
  3176.     checkBoxGrp -edit
  3177.         -v1 `getAttr defaultRenderGlobals.oversamplePfxPostFilter`
  3178.         oversamplePfxPostFilterCheck;
  3179.     
  3180.     string $strokesFile = `getAttr defaultRenderGlobals.strokesDepthFile`;
  3181.     textFieldGrp -edit 
  3182.         -fileName $strokesFile 
  3183.         depthStrokesCheck;
  3184.  
  3185.     // Now update the UI greyed/enabled state.
  3186.     int $value1 = `getAttr defaultRenderGlobals.enableStrokeRender`;
  3187.     if ($value1 == 1) {
  3188.         int $value2 = `getAttr defaultRenderGlobals.onlyRenderStrokes`;
  3189.         int $value3 = `getAttr defaultRenderGlobals.oversamplePaintEffects`;
  3190.         if ($value2 == 1) {
  3191.             textFieldGrp -edit -en true depthStrokesCheck;
  3192.         }
  3193.         else {
  3194.             textFieldGrp -edit -en false depthStrokesCheck;
  3195.         }
  3196.         if( $value3 == 1 ){
  3197.             checkBoxGrp -edit -en true oversamplePfxPostFilterCheck;
  3198.         } else {
  3199.             checkBoxGrp -edit -en false oversamplePfxPostFilterCheck;
  3200.         }
  3201.         checkBoxGrp -edit -en true onlyStrokesCheck;
  3202.         checkBoxGrp -edit -en true oversamplePaintEffectsCheck;
  3203.        } else {
  3204.            textFieldGrp -edit -en false depthStrokesCheck;
  3205.         checkBoxGrp -edit -en false  onlyStrokesCheck;
  3206.         checkBoxGrp -edit -en false  oversamplePaintEffectsCheck;
  3207.         checkBoxGrp -edit -en false  oversamplePfxPostFilterCheck;
  3208.     }
  3209. }
  3210.  
  3211. global proc setRenderGlobalsDepthFile()
  3212. {
  3213.     setAttr defaultRenderGlobals.strokesDepthFile -type "string"
  3214.         `textFieldGrp -q -fileName depthStrokesCheck`;
  3215. }
  3216.  
  3217. global proc createUrchinOptions (string $parent) 
  3218. //
  3219. //  Procedure Name:
  3220. //      createUrchinOptions
  3221. //
  3222. //  Description:
  3223. //      Creates the UI in the "Paint Effects Rendering Options" 
  3224. //        expand/collapse section.
  3225. //
  3226. {
  3227.     setUITemplate -pushTemplate attributeEditorTemplate;
  3228.  
  3229.     setParent $parent;
  3230.     string $cName;
  3231.  
  3232.     // If the UI is created already then just update the attribute values.
  3233.     if (`columnLayout -exists rgUrchinLayout`) {
  3234.         updateUrchinOptions;
  3235.         return;
  3236.     }
  3237.  
  3238.     columnLayout -adjustableColumn true rgUrchinLayout;
  3239.  
  3240.         checkBoxGrp -numberOfCheckBoxes 1
  3241.             -label1 "Enable Stroke Rendering" 
  3242.                 -cc "setAttr defaultRenderGlobals.enableStrokeRender #1; updateUrchinOptions;"
  3243.                 enableStrokesCheck;
  3244.  
  3245.         checkBoxGrp -numberOfCheckBoxes 1
  3246.             -label1 "Oversample" 
  3247.                 -cc "setAttr defaultRenderGlobals.oversamplePaintEffects #1; updateUrchinOptions;"
  3248.                 oversamplePaintEffectsCheck;
  3249.  
  3250.         checkBoxGrp -numberOfCheckBoxes 1
  3251.             -label1 "Oversample Post Filter" 
  3252.                 -cc "setAttr defaultRenderGlobals.oversamplePfxPostFilter #1; updateUrchinOptions;"
  3253.                 oversamplePfxPostFilterCheck;
  3254.         
  3255.         checkBoxGrp -numberOfCheckBoxes 1
  3256.             -label1 "Only Render Strokes" 
  3257.             -cc "setAttr defaultRenderGlobals.onlyRenderStrokes #1 ; updateUrchinOptions;"
  3258.             onlyStrokesCheck;
  3259.  
  3260.         textFieldGrp -label "Read This Depth File"
  3261.             -cc "setRenderGlobalsDepthFile"
  3262.             depthStrokesCheck;
  3263.  
  3264.     setParent ..;
  3265.     setUITemplate -popTemplate;
  3266.  
  3267.     // Make sure the values are right
  3268.     updateUrchinOptions;
  3269. }
  3270.  
  3271. //==================================================================
  3272. //
  3273. // Add Context Sensitive Help
  3274. //
  3275. //==================================================================
  3276.  
  3277. global proc buildRenderGlobalsContextHelpItems(string $nameRoot, string $menuParent)
  3278. {
  3279.     menuItem -label "Help on Render Globals..."
  3280.         -enableCommandRepeat false
  3281.         -command "showHelp RenderGlobals";
  3282. }
  3283.  
  3284. //==================================================================
  3285. //
  3286. // Support for Presets
  3287. //
  3288. //==================================================================
  3289.  
  3290. global proc renderGlobalsRevertToDefault()
  3291. {
  3292.     //
  3293.     // Description:
  3294.     //    This procedure is called when the user chooses Default Settings from
  3295.     //    the Presets->Load Preset menu.
  3296.     //    This procedure performs setAttrs on the attributes of the
  3297.     //    defaultRenderGlobals, defaultResolution and defaultRenderQuality nodes
  3298.     //    to set them to their default values.
  3299.     //    This procedure does not attempt to deal with resolution or quality
  3300.     //    nodes other than the two default nodes. In the future, this procedure
  3301.     //    will be replaced by functionality in the nodePreset command that can
  3302.     //    set an arbitrary node back to its default values.
  3303.     //
  3304.  
  3305.     // Set defaultRenderGlobals to default values
  3306.     //
  3307.     setAttr "defaultRenderGlobals.caching" no;
  3308.     setAttr "defaultRenderGlobals.isHistoricallyInteresting" 2;
  3309.     setAttr "defaultRenderGlobals.nodeState" 0;
  3310.     setAttr "defaultRenderGlobals.renderAll" yes;
  3311.     setAttr "defaultRenderGlobals.ignoreFilmGate" yes;
  3312.     setAttr "defaultRenderGlobals.clipFinalShadedColor" yes;
  3313.     setAttr "defaultRenderGlobals.enableDepthMaps" yes;
  3314.     setAttr "defaultRenderGlobals.enableDefaultLight" yes;
  3315.     setAttr "defaultRenderGlobals.enableStrokeRender" yes;
  3316.     setAttr "defaultRenderGlobals.oversamplePaintEffects" no;
  3317.     setAttr "defaultRenderGlobals.oversamplePfxPostFilter" no;
  3318.     setAttr "defaultRenderGlobals.onlyRenderStrokes" no;
  3319.     setAttr "defaultRenderGlobals.strokesDepthFile" -type "string" "";
  3320.     setAttr "defaultRenderGlobals.imageFormat" 7;
  3321.     setAttr "defaultRenderGlobals.pluginFormat" -type "string" "";
  3322.     setAttr "defaultRenderGlobals.gammaCorrection" 1;
  3323.     setAttr "defaultRenderGlobals.topRegion" 256;
  3324.     setAttr "defaultRenderGlobals.leftRegion" 0;
  3325.     setAttr "defaultRenderGlobals.bottomRegion" 0;
  3326.     setAttr "defaultRenderGlobals.rightRegion" 256;
  3327.     setAttr "defaultRenderGlobals.useRenderRegion" no;
  3328.     setAttr "defaultRenderGlobals.animation" no;
  3329.     setAttr "defaultRenderGlobals.animationRange" 1;
  3330.     setAttr "defaultRenderGlobals.startFrame" 1;
  3331.     setAttr "defaultRenderGlobals.endFrame" 10;
  3332.     setAttr "defaultRenderGlobals.byFrame" 1;
  3333.     setAttr "defaultRenderGlobals.byFrameStep" 1;
  3334.     setAttr "defaultRenderGlobals.modifyExtension" no;
  3335.     setAttr "defaultRenderGlobals.startExtension" 1;
  3336.     setAttr "defaultRenderGlobals.byExtension" 1;
  3337.     setAttr "defaultRenderGlobals.extensionPadding" 1;
  3338.     setAttr "defaultRenderGlobals.fieldExtControl" 0;
  3339.     setAttr "defaultRenderGlobals.stereoExtControl" 0;
  3340.     setAttr "defaultRenderGlobals.outFormatControl" 0;
  3341.     setAttr "defaultRenderGlobals.oddFieldExt" -type "string" "";
  3342.     setAttr "defaultRenderGlobals.evenFieldExt" -type "string" "";
  3343.     setAttr "defaultRenderGlobals.leftStereoExt" -type "string" "";
  3344.     setAttr "defaultRenderGlobals.rightStereoExt" -type "string" "";
  3345.     setAttr "defaultRenderGlobals.outFormatExt" -type "string" "";
  3346.     setAttr "defaultRenderGlobals.useMayaFileName" yes;
  3347.     setAttr "defaultRenderGlobals.useFrameExt" no;
  3348.     setAttr "defaultRenderGlobals.putFrameBeforeExt" no;
  3349.     setAttr "defaultRenderGlobals.imageFilePrefix" -type "string" "";
  3350.     setAttr "defaultRenderGlobals.periodInExt" yes;
  3351.     setAttr "defaultRenderGlobals.composite" no;
  3352.     setAttr "defaultRenderGlobals.compositeThreshold" 0;
  3353.     setAttr "defaultRenderGlobals.shadowsObeyLightLinking" yes;
  3354.     setAttr "defaultRenderGlobals.recursionDepth" 2;
  3355.     setAttr "defaultRenderGlobals.leafPrimitives" 200;
  3356.     setAttr "defaultRenderGlobals.subdivisionPower" 0.25;
  3357.     setAttr "defaultRenderGlobals.subdivisionHashSize" 5;
  3358.     setAttr "defaultRenderGlobals.logRenderPerformance" no;
  3359.     setAttr "defaultRenderGlobals.geometryVector" 20;
  3360.     setAttr "defaultRenderGlobals.shadingVector" 60;
  3361.     setAttr "defaultRenderGlobals.maximumMemory" 48;
  3362.     setAttr "defaultRenderGlobals.numCpusToUse" 0;
  3363.     setAttr "defaultRenderGlobals.shadowPass" no;
  3364.     setAttr "defaultRenderGlobals.iprShadowPass" no;
  3365.     setAttr "defaultRenderGlobals.useFileCache" yes;
  3366.     setAttr "defaultRenderGlobals.optimizeInstances" yes;
  3367.     setAttr "defaultRenderGlobals.reuseTessellations" yes;
  3368.     setAttr "defaultRenderGlobals.motionBlur" no;
  3369.     setAttr "defaultRenderGlobals.motionBlurByFrame" 1;
  3370.     setAttr "defaultRenderGlobals.applyFogInPost" no;
  3371.     setAttr "defaultRenderGlobals.postFogBlur" 1;
  3372.     setAttr "defaultRenderGlobals.preRenderMel" -type "string" "";
  3373.     setAttr "defaultRenderGlobals.postRenderMel" -type "string" "";
  3374.     setAttr "defaultRenderGlobals.preFurRenderMel" -type "string" "";
  3375.     setAttr "defaultRenderGlobals.postFurRenderMel" -type "string" "";
  3376.     setAttr "defaultRenderGlobals.createIprFile" no;
  3377.     setAttr "defaultRenderGlobals.blurLength" 1;
  3378.     setAttr "defaultRenderGlobals.blurSharpness" 1;
  3379.     setAttr "defaultRenderGlobals.smoothValue" 2;
  3380.     setAttr "defaultRenderGlobals.useBlur2DMemoryCap" yes;
  3381.     setAttr "defaultRenderGlobals.blur2DMemoryCap" 200;
  3382.     setAttr "defaultRenderGlobals.motionBlurType" 1;
  3383.     setAttr "defaultRenderGlobals.useDisplacementBoundingBox" yes;
  3384.     setAttr "defaultRenderGlobals.smoothColor" no;
  3385.     setAttr "defaultRenderGlobals.keepMotionVector" no;
  3386.     setAttr "defaultRenderGlobals.iprRenderShading" yes;
  3387.     setAttr "defaultRenderGlobals.iprRenderShadowMaps" yes;
  3388.     setAttr "defaultRenderGlobals.iprRenderMotionBlur" yes;
  3389.     setAttr "defaultRenderGlobals.renderLayerEnable" no;
  3390.     setAttr "defaultRenderGlobals.renderLayerPassEnable" no;
  3391.     setAttr "defaultRenderGlobals.renderGlobalPassEnable" no;
  3392.     setAttr "defaultRenderGlobals.renderLayerSubdirs" no;
  3393.     setAttr "defaultRenderGlobals.forceTileSize" no;
  3394.     setAttr "defaultRenderGlobals.tileWidth" 64;
  3395.     setAttr "defaultRenderGlobals.tileHeight" 64;
  3396.  
  3397.     // Set defaultRenderQuality to default values
  3398.     //
  3399.     setAttr "defaultRenderQuality.caching" no;
  3400.     setAttr "defaultRenderQuality.isHistoricallyInteresting" 2;
  3401.     setAttr "defaultRenderQuality.nodeState" 0;
  3402.     setAttr "defaultRenderQuality.reflections" 1;
  3403.     setAttr "defaultRenderQuality.refractions" 6;
  3404.     setAttr "defaultRenderQuality.shadows" 2;
  3405.     setAttr "defaultRenderQuality.rayTraceBias" 0;
  3406.     setAttr "defaultRenderQuality.edgeAntiAliasing" 3;
  3407.     setAttr "defaultRenderQuality.renderSample" no;
  3408.     setAttr "defaultRenderQuality.useMultiPixelFilter" no;
  3409.     setAttr "defaultRenderQuality.pixelFilterType" 2;
  3410.     setAttr "defaultRenderQuality.pixelFilterWidthX" 2.2000000476837158;
  3411.     setAttr "defaultRenderQuality.pixelFilterWidthY" 2.2000000476837158;
  3412.     setAttr "defaultRenderQuality.plugInFilterWeight" 1;
  3413.     setAttr "defaultRenderQuality.shadingSamples" 1;
  3414.     setAttr "defaultRenderQuality.maxShadingSamples" 8;
  3415.     setAttr "defaultRenderQuality.visibilitySamples" 1;
  3416.     setAttr "defaultRenderQuality.maxVisibilitySamples" 4;
  3417.     setAttr "defaultRenderQuality.volumeSamples" 1;
  3418.     setAttr "defaultRenderQuality.particleSamples" 1;
  3419.     setAttr "defaultRenderQuality.enableRaytracing" no;
  3420.     setAttr "defaultRenderQuality.redThreshold" 0.40000000596046448;
  3421.     setAttr "defaultRenderQuality.greenThreshold" 0.30000001192092896;
  3422.     setAttr "defaultRenderQuality.blueThreshold" 0.60000002384185791;
  3423.     setAttr "defaultRenderQuality.coverageThreshold" 0.125;
  3424.  
  3425.     // Set defaultResolution to default values
  3426.     //
  3427.     setAttr "defaultResolution.caching" no;
  3428.     setAttr "defaultResolution.isHistoricallyInteresting" 2;
  3429.     setAttr "defaultResolution.nodeState" 0;
  3430.     setAttr "defaultResolution.width" 320;
  3431.     setAttr "defaultResolution.height" 240;
  3432.     setAttr "defaultResolution.pixelAspect" 0;
  3433.     setAttr "defaultResolution.aspectLock" no;
  3434.     setAttr "defaultResolution.deviceAspectRatio" 1.3333300352096558;
  3435.     setAttr "defaultResolution.lockDeviceAspectRatio" no;
  3436.     setAttr "defaultResolution.oddFieldFirst" yes;
  3437.     setAttr "defaultResolution.fields" 0;
  3438.     setAttr "defaultResolution.zerothScanline" 0;
  3439. }
  3440.  
  3441. global proc buildRenderGlobalsPresetsMenu()
  3442. {
  3443.     //
  3444.     // Description:
  3445.     //    This procedure builds the Presets menu in the render globals window.
  3446.     //
  3447.  
  3448.     setParent renderGlobalsWindow;
  3449.     menu -edit -deleteAllItems presetsMenu;
  3450.  
  3451.     setParent -menu presetsMenu;
  3452.  
  3453.     menuItem 
  3454.         -label "Save Settings as Preset..."
  3455.         -command ("saveNodePresetDialog");
  3456.  
  3457.     string $presetArray[];
  3458.     $presetArray = `nodePreset -list defaultRenderGlobals`;
  3459.  
  3460.     menuItem 
  3461.         -label "Load Preset"
  3462.         -subMenu true;
  3463.     
  3464.         menuItem 
  3465.             -label "Default Settings"
  3466.             -command 
  3467.                 ("renderGlobalsRevertToDefault; updateAllRenderGlobals;");
  3468.         
  3469.         menuItem -divider true;
  3470.  
  3471.         // Add a menu item for each available preset.
  3472.         //
  3473.         int $i;
  3474.         for ($i = 0; $i < size($presetArray); $i++)
  3475.         {
  3476.             menuItem
  3477.                 -label $presetArray[$i]
  3478.                 -command (
  3479.                     "nodePreset -load defaultRenderGlobals \""
  3480.                         + $presetArray[$i]
  3481.                         + "\"; "
  3482.                         + "nodePreset -load defaultRenderQuality \""
  3483.                         + $presetArray[$i]
  3484.                         + "\"; "
  3485.                         + "nodePreset -load defaultResolution \""
  3486.                         + $presetArray[$i]
  3487.                         + "\"; "
  3488.                         + "updateAllRenderGlobals");
  3489.         }
  3490.     setParent -menu ..; // from Load Preset menu
  3491.     menuItem 
  3492.         -label "Delete Preset"
  3493.         -subMenu true;
  3494.     
  3495.         if (size($presetArray) == 0)
  3496.         {
  3497.             menuItem 
  3498.                 -label "No Presets Currently Exist"
  3499.                 -enable false;
  3500.         }
  3501.         else
  3502.         {
  3503.             // Add a menu item to be able to delete each available preset.
  3504.             //
  3505.             int $i;
  3506.             for ($i = 0; $i < size($presetArray); $i++)
  3507.             {
  3508.                 menuItem
  3509.                     -label $presetArray[$i]
  3510.                     -command (
  3511.                         "nodePresetConfirmDeleteDialog \""
  3512.                             + $presetArray[$i]
  3513.                             + "\"; ");
  3514.             }
  3515.         }
  3516.     setParent -menu ..; // from Delete Preset menu
  3517.  
  3518.     menuItem
  3519.         -label "Set Preferred Preset"
  3520.         -subMenu true;
  3521.         
  3522.         int $preferredPresetExists;
  3523.         string $preferredPresetName;
  3524.  
  3525.         if (`optionVar -exists defaultRenderGlobalsPreferredPreset`)
  3526.         {
  3527.             $preferredPresetExists = true;
  3528.             $preferredPresetName = 
  3529.                 `optionVar -query defaultRenderGlobalsPreferredPreset`;
  3530.         }
  3531.  
  3532.         menuItem 
  3533.             -label "Default Settings"
  3534.             -checkBox (!$preferredPresetExists)
  3535.             -command (
  3536.                 "optionVar -remove defaultRenderGlobalsPreferredPreset;"
  3537.                 + "optionVar -remove defaultRenderQualityPreferredPreset;"
  3538.                 + "optionVar -remove defaultResolutionPreferredPreset;");
  3539.  
  3540.         menuItem -divider true;
  3541.  
  3542.         // Add a menu item to be able to set each available preset as your
  3543.         // preferred preset (to which render globals will be initialized
  3544.         // when you create a new file).
  3545.         //
  3546.         int $i;
  3547.         int $checkBoxValue;
  3548.  
  3549.         for ($i = 0; $i < size($presetArray); $i++)
  3550.         {
  3551.             $checkBoxValue = false;
  3552.             if ($preferredPresetExists)
  3553.             {
  3554.                 $checkBoxValue = ($presetArray[$i] == $preferredPresetName);
  3555.             }
  3556.             menuItem
  3557.                 -label $presetArray[$i]
  3558.                 -checkBox $checkBoxValue
  3559.                 -command (
  3560.                     "optionVar -stringValue " 
  3561.                         + "\"defaultRenderGlobalsPreferredPreset\" \""
  3562.                         + $presetArray[$i] 
  3563.                         + "\"; optionVar -stringValue " 
  3564.                         + "\"defaultRenderQualityPreferredPreset\" \""
  3565.                         + $presetArray[$i] 
  3566.                         + "\"; optionVar -stringValue " 
  3567.                         + "\"defaultResolutionPreferredPreset\" \""
  3568.                         + $presetArray[$i] 
  3569.                         + "\";");
  3570.         }
  3571.     setParent -menu ..; // from Set Preferred Preset menu
  3572. }
  3573.  
  3574. //==================================================================
  3575. //
  3576. // Starting the Window building section
  3577. //
  3578. //==================================================================
  3579.  
  3580. global proc renderGlobalsWindow () 
  3581. //
  3582. //  Procedure Name:
  3583. //      renderGlobalsWindow
  3584. //
  3585. //  Description:
  3586. //        This procedure only builds the UI for the window.
  3587. //        The update* procedures make sure that the values are valid.
  3588. //        And the change* procedures do the editting of the values.
  3589. //
  3590. {
  3591.     // Unless the user has set the USE_OLD_RENDER_GLOBALS_WINDOW environment
  3592.     // variable, we will open the new unified render globals window.
  3593.     //
  3594.     if (size(`getenv "USE_OLD_RENDER_GLOBALS_WINDOW"`) == 0)
  3595.     {
  3596.         unifiedRenderGlobalsWindow();
  3597.         return;
  3598.     }
  3599.  
  3600.     // If the window exists already, just show it.
  3601.     //
  3602.     if (`window -exists renderGlobalsWindow`) {
  3603.         showWindow renderGlobalsWindow;
  3604.         updateAllRenderGlobals;
  3605.         return;
  3606.     }    
  3607.  
  3608.     // Create the window
  3609.     //
  3610.     window -title "Render Globals" 
  3611.         -wh 422 670 -tlc 200 220 
  3612.         -mb true -retain
  3613.         -iconName "R.Globals" renderGlobalsWindow;
  3614.  
  3615.     // Set up the menus
  3616.     //
  3617.     menu -l "Edit";
  3618.     menuItem -l "Hardware Render Globals..."
  3619.         -c "editRenderGlobalsRW";
  3620.     menuItem -l "Change Project Image Directory..."
  3621.         -c "EditProject";
  3622.  
  3623.     menu -label "Presets"
  3624.         -postMenuCommand "buildRenderGlobalsPresetsMenu"
  3625.         presetsMenu;
  3626.  
  3627.     //    Adds support for the Context Sensitive Help Menu.
  3628.     //
  3629.     addContextHelpProc "renderGlobalsWindow" "buildRenderGlobalsContextHelpItems";
  3630.  
  3631.     doHelpMenu "renderGlobalsWindow" "renderGlobalsWindow";
  3632.  
  3633.     setUITemplate -pushTemplate attributeEditorTemplate;
  3634.  
  3635.     formLayout rgMainForm;
  3636.  
  3637.     //--------------------------------------------------------------          
  3638.     // Example File Name area
  3639.     //--------------------------------------------------------------          
  3640.     
  3641.     frameLayout -labelVisible false -cll false -cl false exampleLayout;
  3642.     columnLayout -adjustableColumn true;
  3643.         text -align "left" -font "boldLabelFont" -label "" exampleText0;
  3644.         text -align "left" -font "boldLabelFont" -label "" exampleText1;
  3645.         text -align "left" -font "boldLabelFont" -label "" exampleText2;
  3646.  
  3647.     setParent ..;
  3648.     setParent ..;
  3649.  
  3650.     //--------------------------------------------------------------          
  3651.     // Information area starts
  3652.     //--------------------------------------------------------------          
  3653.     
  3654.     scrollLayout -hst 0 rgMainLayout;
  3655.     string $parent = `columnLayout -adjustableColumn true`;
  3656.  
  3657.     // Image File Name
  3658.     //
  3659.     frameLayout -label "Image File Output" 
  3660.         -cll true -cl 0
  3661.         rgImageFileFrame;
  3662.     
  3663.         // This section defaults open so always create the UI
  3664.         createImageFile ("rgImageFileFrame");
  3665.  
  3666.     setParent ..;
  3667.  
  3668.     // Resolution Section
  3669.     //
  3670.     frameLayout -label "Resolution" 
  3671.         -cll true -cl 1
  3672.         -preExpandCommand "createResolution (\"rgResolutionFrame\")" 
  3673.         rgResolutionFrame;
  3674.     setParent ..;
  3675.  
  3676.     // Field Options
  3677.     //
  3678.     frameLayout -label "Field Options" 
  3679.         -cll true -cl 1
  3680.         -preExpandCommand "createFieldOptions (\"rgFieldOptionsFrame\")" 
  3681.         rgFieldOptionsFrame;
  3682.     setParent ..;            
  3683.     
  3684.     // Anti-aliasing quality section
  3685.     //
  3686.     frameLayout -label "Anti-aliasing Quality" 
  3687.         -cll true -cl 1
  3688.         -preExpandCommand "createRenderQuality (\"rgQualityFrame\")" 
  3689.         rgQualityFrame;
  3690.     setParent ..;
  3691.  
  3692.     // Raytracing quality section
  3693.     //
  3694.     frameLayout -label "Raytracing Quality" 
  3695.         -cll true -cl 1
  3696.         -preExpandCommand "createRayTraceQuality (\"rgRayTraceFrame\")" 
  3697.         rgRayTraceFrame;
  3698.     setParent ..;
  3699.     
  3700.  
  3701.     // Extension Options
  3702.     //
  3703.     frameLayout -label "Modify Extension" 
  3704.         -cll true -cl 1
  3705.         rgExtOptionsFrame;
  3706.         
  3707.         // Always create this since it is needed by the first section
  3708.         createExtensionOptions ("rgExtOptionsFrame");
  3709.         
  3710.     setParent ..;
  3711.  
  3712.     // Frame Options
  3713.     //
  3714.     frameLayout -label "Renumber Frames" 
  3715.         -cll true -cl 1
  3716.         -preExpandCommand "createFrameOptions (\"rgFrameOptionsFrame\")" 
  3717.         rgFrameOptionsFrame;
  3718.     setParent ..;
  3719.  
  3720.     // Motion Blur
  3721.     //
  3722.     frameLayout -label "Motion Blur" 
  3723.         -cll true -cl 1
  3724.         -preExpandCommand "createMotionBlur (\"rgBlurFrame\")" 
  3725.         rgBlurFrame;
  3726.     setParent ..;            
  3727.  
  3728.     // Render Options
  3729.     //
  3730.     frameLayout -label "Render Options"
  3731.         -cll true -cl 1
  3732.         -preExpandCommand "createRenderOptions (\"rgOptionFrame\")" 
  3733.         rgOptionFrame;
  3734.     setParent ..;
  3735.  
  3736.     // Performance Options
  3737.     //
  3738.     frameLayout -label "Memory and Performance Options"
  3739.         -cll true -cl 1
  3740.         -preExpandCommand "createPerformanceOptions (\"rgPerfFrame\")" 
  3741.         rgPerfFrame;
  3742.     setParent ..;
  3743.  
  3744.     // IPR Options
  3745.     //
  3746.     frameLayout -label "IPR Options"
  3747.         -cll true -cl 1
  3748.         rgIPRFrame;
  3749.     createIPROptions("rgIPRFrame"); 
  3750.     setParent ..;
  3751.  
  3752.     // Render Layer/Pass Options
  3753.     //
  3754.     frameLayout -label "Render Layer/Pass Control"
  3755.         -cll true -cl 1
  3756.         -preExpandCommand "createRenderLayerOptions (\"rgRenderLayerFrame\")"
  3757.         rgRenderLayerFrame;
  3758.     setParent ..;
  3759.  
  3760.     if (`isTrue MayaCreatorExists`) {
  3761.         // Urchin Options
  3762.         frameLayout -label "Paint Effects Rendering Options"
  3763.             -cll true -cl 1
  3764.             -preExpandCommand "createUrchinOptions (\"rgUrchinFrame\")"
  3765.             rgUrchinFrame;
  3766.         setParent ..;
  3767.     }
  3768.  
  3769.     // These end off the layouts of the information area
  3770.     setParent ..;
  3771.     setParent ..;
  3772.  
  3773.     //--------------------------------------------------------------          
  3774.     // Button area starts
  3775.     //--------------------------------------------------------------          
  3776.  
  3777.     button -l "Close" 
  3778.         -h 26
  3779.         -align "center"
  3780.         -c "window -e -vis 0 renderGlobalsWindow" 
  3781.         rgCloseBtn;
  3782.  
  3783.     setParent ..;
  3784.  
  3785.     // Fix up the layout
  3786.     
  3787.     formLayout -edit
  3788.     
  3789.         -af exampleLayout "top" 0 
  3790.         -af exampleLayout "left" 0 
  3791.         -an exampleLayout "bottom"
  3792.         -af exampleLayout "right" 0 
  3793.  
  3794.         -ac rgMainLayout "top" 5 exampleLayout
  3795.         -af rgMainLayout "left" 0 
  3796.         -af rgMainLayout "right" 0 
  3797.         -ac rgMainLayout "bottom" 5 rgCloseBtn
  3798.  
  3799.         -an rgCloseBtn "top"
  3800.         -af rgCloseBtn "bottom" 5
  3801.         -af rgCloseBtn "left" 5
  3802.         -af rgCloseBtn "right" 5
  3803.         rgMainForm;
  3804.  
  3805.     setUITemplate -popTemplate ;
  3806.  
  3807.     //--------------------------------------------------------------
  3808.     // Update and show window
  3809.     //--------------------------------------------------------------
  3810.  
  3811.     updateImageDirectory;
  3812.     updateImageFile;
  3813.     updateRenderableCamera;
  3814.     updateFrames;
  3815.     updateFileOutputFeedback;
  3816.     
  3817.     showWindow renderGlobalsWindow;
  3818.  
  3819.     // The -replacePrevious flag removes all scriptJobs from
  3820.     // this window.  Then these two are added back.
  3821.     //
  3822.     scriptJob -p renderGlobalsWindow -replacePrevious
  3823.         -e SceneOpened updateAllRenderGlobals;
  3824.  
  3825.     scriptJob -p renderGlobalsWindow
  3826.         -e workspaceChanged updateImageDirectory;
  3827.  
  3828. }
  3829.  
  3830. global proc updateAllRenderGlobals()
  3831. {
  3832.     updateImageFile;
  3833.     updateRenderableCamera;
  3834.     updateFrames;
  3835.     updateFileOutputFeedback;
  3836.     if (`frameLayout -q -cl rgResolutionFrame` == 0) {
  3837.         updateResolution;
  3838.     }
  3839.     if (`frameLayout -q -cl rgQualityFrame` == 0) {
  3840.         updateRenderQuality;
  3841.     }
  3842.     if (`frameLayout -q -cl rgRayTraceFrame` == 0) {
  3843.         updateRaytraceQuality;
  3844.     }
  3845.     if (`frameLayout -q -cl rgExtOptionsFrame` == 0) {
  3846.         updateExtOptions;
  3847.     }
  3848.     if (`frameLayout -q -cl rgFieldOptionsFrame` == 0) {
  3849.         updateFieldOptions;
  3850.     }
  3851.     if (`frameLayout -q -cl rgBlurFrame` == 0) {
  3852.         updateMotionBlur;
  3853.     }
  3854.     if (`frameLayout -q -cl rgOptionFrame` == 0) {
  3855.         updateRenderOptions;
  3856.     }
  3857.     if (`frameLayout -q -cl rgPerfFrame` == 0) {
  3858.         updatePerformanceOptions;
  3859.     }
  3860.     if (`frameLayout -q -cl rgIPRFrame` == 0) {
  3861.         updateIPROptions;
  3862.     }
  3863.     if (`frameLayout -q -cl rgRenderLayerFrame` == 0) {
  3864.         updateRenderLayerOptions;
  3865.     }
  3866.     if (`isTrue MayaCreatorExists`) {
  3867.         if (`frameLayout -q -cl rgUrchinFrame` == 0) {
  3868.             updateUrchinOptions;
  3869.         }
  3870.     }
  3871. }
  3872.  
  3873. global proc checkAspectLockWidth ( string $nodeName )
  3874. {
  3875.     float $deviceAspect;
  3876.  
  3877.     if ( `getAttr ( $nodeName + ".aspectLock" )` ) {
  3878.         // AEadjustHeight
  3879.         int $value = `getAttr ( $nodeName + ".width" )`;
  3880.     
  3881.         float $aspect = `getAttr ( $nodeName + ".pixelAspect" )`;
  3882.     
  3883.         if ( $aspect > 0.0 ){
  3884.             int $rez = $aspect * $value;
  3885.             int $oldrez = `getAttr ( $nodeName + ".height" )`;
  3886.             if ($rez - $oldrez > 1 || $oldrez - $rez > 1) {
  3887.                 setAttr ( $nodeName + ".height" ) $rez;
  3888.             }
  3889.         } else {
  3890.             checkAspectLock $nodeName;
  3891.         }
  3892.     }
  3893.  
  3894.     if ( `getAttr ( $nodeName + ".lockDeviceAspectRatio" )` == 0 ) {
  3895.         $deviceAspect = `getAttr ( $nodeName + ".width" )`;
  3896.         $deviceAspect = $deviceAspect / `getAttr ( $nodeName + ".height" )`;
  3897.         setAttr ( $nodeName + ".deviceAspectRatio" ) $deviceAspect;
  3898.     }
  3899. }
  3900.  
  3901. global proc checkAspectLockHeight ( string $nodeName )
  3902. {
  3903.     float $deviceAspect;
  3904.  
  3905.     if ( `getAttr ( $nodeName + ".aspectLock" )` ) {
  3906.         // AEadjustWidth
  3907.         int $value = `getAttr ( $nodeName + ".height" )`;
  3908.         
  3909.         float $aspect = `getAttr ( $nodeName + ".pixelAspect" )`;
  3910.     
  3911.         if ( $aspect > 0.0 ){
  3912.             int $rez = $value / $aspect;
  3913.             int $oldrez = `getAttr ( $nodeName + ".width" )`;
  3914.             if ($rez - $oldrez > 1 || $oldrez - $rez > 1) {
  3915.                 setAttr ( $nodeName + ".width" ) $rez;
  3916.             }
  3917.         } else {
  3918.             checkAspectLock $nodeName;
  3919.         }
  3920.     }
  3921.  
  3922.     if ( `getAttr ( $nodeName + ".lockDeviceAspectRatio" )` == 0 ) {
  3923.         $deviceAspect = `getAttr ( $nodeName + ".width" )`;
  3924.         $deviceAspect = $deviceAspect / `getAttr ( $nodeName + ".height" )`;
  3925.         setAttr ( $nodeName + ".deviceAspectRatio" ) $deviceAspect;
  3926.     }
  3927. }
  3928.  
  3929. global proc checkAspectLock ( string $nodeName )
  3930. {
  3931.     // AEadjustPixelAspect
  3932.     int $lockOn = `getAttr ( $nodeName + ".aspectLock" )`;
  3933.  
  3934.     if ($lockOn) {
  3935.         float $h = `getAttr ( $nodeName + ".height" )`;
  3936.         float $w = `getAttr ( $nodeName + ".width" )`;
  3937.         float $aspect = $h / $w;
  3938.         setAttr ( $nodeName + ".pixelAspect" ) $aspect;
  3939.     } else {
  3940.         setAttr ( $nodeName + ".pixelAspect" ) 0.0;
  3941.     }
  3942. }
  3943.  
  3944. global proc rgPixelAspectReplace(string $nodeName)
  3945. {
  3946.     string $aspectAttr = $nodeName + ".deviceAspectRatio";
  3947.     string $widthAttr = $nodeName + ".width";
  3948.     string $heightAttr = $nodeName + ".height";
  3949.     float  $aspect = (float) `getAttr $widthAttr` / (float) `getAttr $heightAttr`;
  3950.     $aspect = `getAttr $aspectAttr` / $aspect;
  3951.  
  3952.     floatFieldGrp -e -v1 $aspect pixRatio;
  3953. }
  3954.  
  3955. global proc rgAdjustPixelAspect(string $nodeName)
  3956. {
  3957.     setParent renderGlobalsWindow;
  3958.     string $aspectAttr = $nodeName + ".deviceAspectRatio";
  3959.     string $widthAttr = $nodeName + ".width";
  3960.     string $heightAttr = $nodeName + ".height";
  3961.     float  $pixelAspect = (float) `getAttr $widthAttr`
  3962.                             / (float) `getAttr $heightAttr`;
  3963.     $pixelAspect = `getAttr $aspectAttr` / $pixelAspect;
  3964.     floatFieldGrp -e -v1 $pixelAspect pixRatio;
  3965. }
  3966.  
  3967. global proc rgAdjustDeviceAspect(string $nodeName)
  3968. {
  3969.     setParent renderGlobalsWindow;
  3970.     string $devAspectAttr = $nodeName + ".deviceAspectRatio";
  3971.     string $widthAttr = $nodeName + ".width";
  3972.     string $heightAttr = $nodeName + ".height";
  3973.  
  3974.     float $pixelAspect = `floatFieldGrp -q -v1 pixRatio`;
  3975.     float $aspect = (float) `getAttr $widthAttr`
  3976.                     / (float) `getAttr $heightAttr`;
  3977.     $aspect = $pixelAspect * $aspect;
  3978.     setAttr $devAspectAttr $aspect;
  3979.     floatFieldGrp -edit -v1 $aspect resRatio;
  3980. }
  3981.  
  3982. global proc updateDeviceAspectRatio()
  3983. {
  3984.     setAttr defaultResolution.deviceAspectRatio
  3985.         `floatFieldGrp -q -v1 resRatio`;
  3986.     rgAdjustPixelAspect "defaultResolution";
  3987.     updateResolution;
  3988. }
  3989.  
  3990. global proc updateRenderLayerLayout( int $doLayers, int $doPasses )
  3991. {
  3992.     updateRenderLayerFilters;
  3993.  
  3994.     if ( $doLayers )
  3995.     {
  3996.         if ( $doPasses )
  3997.         {
  3998.             spreadSheetEditor
  3999.                 -e
  4000.                 -filter renderLayerFilter
  4001.                 -fal {"rndr","b","cp","s","di","sp"}
  4002.                 "layerOutliner";
  4003.  
  4004.         }
  4005.         else
  4006.         {
  4007.             spreadSheetEditor
  4008.                 -e
  4009.                 -filter renderLayerFilter
  4010.                 -fal {"rndr"}
  4011.                 "layerOutliner";
  4012.  
  4013.         }
  4014.  
  4015.         checkBoxGrp -e        
  4016.             -ed true
  4017.             -en1 true
  4018.             renderLayerPassEnable;    
  4019.  
  4020.         checkBoxGrp -e        
  4021.             -ed false
  4022.             -en1 false
  4023.             renderGlobalPassEnable;    
  4024.  
  4025.         frameLayout
  4026.             -e
  4027.             -m true
  4028.             "layerAttrLayout";
  4029.  
  4030.     }
  4031.     else
  4032.     {
  4033.         if ( $doPasses )
  4034.         {
  4035.             spreadSheetEditor
  4036.                 -e
  4037.                 -filter glblRenderFilter
  4038.                 -fal {"b","cp","s","di","sp"}
  4039.                 "layerOutliner";
  4040.  
  4041.             frameLayout
  4042.                 -e
  4043.                 -m true
  4044.                 "layerAttrLayout";
  4045.  
  4046.         }
  4047.         else
  4048.         {
  4049.             frameLayout
  4050.                 -e
  4051.                 -m false
  4052.                 "layerAttrLayout";
  4053.         }
  4054.  
  4055.         checkBoxGrp -e        
  4056.             -ed true
  4057.             -en1 true 
  4058.             renderGlobalPassEnable;    
  4059.  
  4060.         checkBoxGrp -e        
  4061.             -ed false
  4062.             -en1 false 
  4063.             renderLayerPassEnable;    
  4064.     }
  4065. }
  4066.  
  4067. global proc updateRenderLayerOptions ()
  4068. //
  4069. //  Procedure Name:
  4070. //      updateRenderLayerOptions
  4071. //
  4072. //  Description:
  4073. //      Gets the real values from the option vars and sets the UI based
  4074. //        on these values.  This procedure updates all of the RL/RP
  4075. //        values.
  4076. //
  4077. { 
  4078.     int $doLayers = `getAttr "defaultRenderGlobals.renderLayerEnable"`;
  4079.     checkBoxGrp -edit -v1 $doLayers renderLayerEnable;
  4080.  
  4081.     int $doLayerPasses = `getAttr "defaultRenderGlobals.renderLayerPassEnable"`;
  4082.     checkBoxGrp -edit -v1 $doLayerPasses renderLayerPassEnable;
  4083.  
  4084.     int $doGlobalPasses = `getAttr "defaultRenderGlobals.renderGlobalPassEnable"`;
  4085.     checkBoxGrp -edit -v1 $doGlobalPasses renderGlobalPassEnable;
  4086.  
  4087.     int $doSubdirs = `getAttr "defaultRenderGlobals.renderLayerSubdirs"`;
  4088.     checkBoxGrp -edit -v1 $doSubdirs renderLayerSubdirs;
  4089.     
  4090.     if ( $doLayers ) {
  4091.         updateRenderLayerLayout( true, $doLayerPasses );
  4092.     }
  4093.     else {
  4094.         updateRenderLayerLayout( false, $doGlobalPasses );
  4095.     }    
  4096. }
  4097.  
  4098. global proc updateRenderLayerEnable()
  4099. {
  4100.     int $doPasses;
  4101.     int $doLayers = `checkBoxGrp -q -v1 renderLayerEnable`;
  4102.     setAttr defaultRenderGlobals.renderLayerEnable $doLayers;
  4103.     if ( $doLayers ) {
  4104.         $doPasses = `checkBoxGrp -q -v1 renderLayerPassEnable`;
  4105.     }
  4106.     else {
  4107.         $doPasses = `checkBoxGrp -q -v1 renderGlobalPassEnable`;
  4108.     }
  4109.  
  4110.     updateRenderLayerLayout( $doLayers, $doPasses );
  4111. }
  4112.  
  4113. global proc updateRenderLayerPassEnable()
  4114. {
  4115.     int $doLayers = `checkBoxGrp -q -v1 renderLayerEnable`;
  4116.     int $doPasses = `checkBoxGrp -q -v1 renderLayerPassEnable`;
  4117.     setAttr defaultRenderGlobals.renderLayerPassEnable $doPasses;
  4118.     updateRenderLayerLayout( $doLayers, $doPasses );
  4119. }
  4120.  
  4121. global proc updateRenderGlobalPassEnable()
  4122. {
  4123.     int $doLayers = `checkBoxGrp -q -v1 renderLayerEnable`;
  4124.     int $doPasses = `checkBoxGrp -q -v1 renderGlobalPassEnable`;
  4125.     setAttr defaultRenderGlobals.renderGlobalPassEnable $doPasses;
  4126.     updateRenderLayerLayout( $doLayers, $doPasses );
  4127. }
  4128.  
  4129. //global proc updateRenderLayerSubdirs()
  4130. //{
  4131.     //int $doSubdirs = `checkBoxGrp -q -v1 renderLayerSubdirs`;
  4132.     //setAttr defaultRenderGlobals.renderLayerSubdirs $doPasses;
  4133.     //////////optionVar -intValue renderLayerSubdirs $doSubdirs;
  4134. //}
  4135.  
  4136.  
  4137. global proc createRenderLayerOptions (string $parent) 
  4138. //
  4139. //  Procedure Name:
  4140. //      createRenderLayerOptions
  4141. //
  4142. //  Description:
  4143. //      Creates the UI in the "Render Layer/Pass Control" 
  4144. //        expand/collapse section.
  4145. //
  4146. {
  4147.     setUITemplate -pushTemplate attributeEditorTemplate;
  4148.  
  4149.     setParent $parent;
  4150.     string $cName;
  4151.  
  4152.     // Set up the spreadsheet filters
  4153.     updateRenderLayerFilters;
  4154.  
  4155.     // If the UI is created already then just update the attribute values.
  4156.     if (`columnLayout -exists rgRenderLayerLayout`) {
  4157.         updateRenderLayerOptions;
  4158.         return;
  4159.     }
  4160.  
  4161.     //columnLayout -adjustableColumn true rgRenderLayerLayout;
  4162.     columnLayout -adjustableColumn true rgRenderLayerLayout;
  4163.         checkBoxGrp -numberOfCheckBoxes 1
  4164.             -label1 "Enable Render Layers" 
  4165.             -cc "updateRenderLayerEnable"
  4166.             renderLayerEnable;
  4167.  
  4168.     
  4169.         checkBoxGrp -numberOfCheckBoxes 1
  4170.             -label1 "Enable Render Layer Passes" 
  4171.             -cc "updateRenderLayerPassEnable"
  4172.             renderLayerPassEnable;    
  4173.  
  4174.         checkBoxGrp -numberOfCheckBoxes 1
  4175.             -label1 "Enable Global Passes" 
  4176.             -cc "updateRenderGlobalPassEnable"
  4177.             renderGlobalPassEnable;    
  4178.  
  4179.         separator;
  4180.  
  4181.         checkBoxGrp -numberOfCheckBoxes 1
  4182.             -label1 "Output to Subdirectories" 
  4183.             //-cc "updateRenderLayerSubdirs"
  4184.             -cc "setAttr defaultRenderGlobals.renderLayerSubdirs #1"
  4185.             renderLayerSubdirs;
  4186.  
  4187.         //columnLayout bbby;
  4188.         //setParent ..;
  4189.         //button  -label "Save Composition File...";
  4190.  
  4191.         frameLayout
  4192.             -label "Render Layers"
  4193.             -labelVisible false
  4194.             -borderVisible false
  4195.             -collapsable false
  4196. //            -m false
  4197.             layerAttrLayout;
  4198.  
  4199.             columnLayout -adjustableColumn true layerLyt;
  4200.  
  4201.             separator;
  4202.  
  4203.              selectionConnection -wl -parent layerLyt aList;
  4204.             spreadSheetEditor 
  4205.                 -mainListConnection aList
  4206.                 -ko false
  4207.                 -ln true
  4208.                 -fal {"rndr"}
  4209.                 -filter renderLayerFilter
  4210.                 layerOutliner;
  4211.             setParent ..;
  4212.  
  4213.         setParent ..;
  4214.  
  4215.     setParent ..;
  4216.  
  4217.     setUITemplate -popTemplate;
  4218.  
  4219.     // Make sure the values are right
  4220.     updateRenderLayerOptions;
  4221. }
  4222.